繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- [原创]asp下用实现模板加载的的几种方法总结
- asp下利用fso实现文件夹或文件移动改名等操作函数
- asp cint clng的范围与防止cint和clng的溢出解决方法大全
- asp防范跨站点脚本攻击的的方法
- 独孤剑写的马克斯迅雷片库采集插件1.4 官方最新版提供下载了
- 根据日期得到生肖的ASP函数
- 不错的主要用于加密的vbs(asp)位移运算类
- Script.VBS.Agent.ai juan.vbs专杀
- 循环取值Request.QueryString的用法
- asp下实现字符串的补充fill()
- 无服务器做任意二级米子站
- 几种另类的ASP后门
- asp事物功能简单小应用
- ASP获取网页全部图片地址并保存为数组的正则
- 通过客户端验证上传图片文件大小的ASP源码
- asp下计算分页的几种方法
- 谈动态多行多列，循环行和列，输出M行N列的ASP代码
- asp在线执行sql语句的函数
- asp正则html的图片,对图自动缩放大小
- 文件名 正则表达式提取方法
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 68 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
