繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- ASP中数据库调用中常见错误的现象和解决方法
- ASP取出HTML里面的图片地址的函数
- 关于分页查询和性能问题
- 利用Asp生成整站静态
- 用ASP+XMLHTTP编写一个天气预报程序
- 轻松检测浏览器是否接受Cookies信息
- 净化网络环境：ASP程序实现过滤脏话
- 入门：防范SQL注入攻击的新办法
- 如何对ASP.NET进行性能优化
- ASP无法更新ACCESS数据库解决方法
- ASP：利用ASP把图片上传到数据库
- ASP：用ASP编程实现网络内容快速查找
- ASP:用ASP打造一个小型的网页BBS系统
- ASP:用Asp编程实现QQ的在线情况查询
- 通过表单创建word的一个例子
- 在ASP中轻松实现记录集分页显示
- ASP中实现小偷程序的原理和简单示例
- ASP：6行代码实现无组件上传
- 实用篇:用asp实现QQ在线查询
- 如何轻松打造ASP计数器
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 43 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
