繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- ASP+XML实例演练编程代码
- asp下利用XMLHTTP 从其他页面获取数据的代码
- asp下实现IP限制函数代码
- asp下IP地址分段计算函数
- asp身份证验证代码函数
- 用Asp隐藏文件路径，实现防盗链 的代码
- ASP生成柱型体，折线图，饼图源代码提供了
- 用asp实现网址和邮件地址的转换函数
- asp下最简洁的多重查询的解决方案
- asp下用datediff实现计算两个时间差的函数
- asp下实现记录集内随机取记录的代码
- asp下轻松实现将上传图片到数据库的代码
- [原创]站长感慨asp编程究竟何去何从
- fso asp生成静态html的代码
- ASP版实现cookies注入加速工具
- ASP实现网页打开任何类型文件都提示保存的方法附代码
- asp下使用数组存放数据的代码
- 一句话 asp木马加密版 彻底突破杀毒软件
- asp清空application的方法
- 使用asp下的adodb.stream 下载文件而不是打开
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 61 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
