save.asp

<!-- #include file="adovbs.inc" -->
<%
' Constants file included above.

' 如果文件存在则删除
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(Server.MapPath("db_xml.xml")) Then
 objFSO.DeleteFile Server.MapPath("db_xml.xml")
End IF
Set objFSO = Nothing

'变量声明
Dim cnnXML  ' ADO connection
Dim rstXML  ' ADO recordset

'创建数据连接对象
Set cnnXML = Server.CreateObject("ADODB.Connection")

' 这是连接access数据库的例子:
'cnnXML.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" _
' & Server.MapPath("db_scratch.mdb") & ";"

' 下面以Sqlserver为例子讲解:
cnnXML.Open "Provider=SQLOLEDB;Data Source=10.2.1.214;" _
 & "Initial Catalog=samples;User Id=samples;Password=password;" _
 & "Connect Timeout=15;Network Library=dbmssocn;"

Set rstXML = Server.CreateObject("ADODB.Recordset")
Set rstXML = cnnXML.Execute("SELECT * FROM scratch ORDER BY id;")

Response.Write "<p>Saving data as XML...</p>" & vbCrLf

' 保存至xml格式.
rstXML.Save Server.MapPath("db_xml.xml"), adPersistXML

' 关闭对象、释放资源
rstXML.Close
Set rstXML = Nothing
cnnXML.Close
Set cnnXML = Nothing

Response.Write "<p>XML file written...</p>" & vbCrLf
Response.Write "<p>Click <a href=""db_xml.xml"">here</a> to view the file.</p>" & vbCrLf
%>

制做行背景颜色交替变换的表格 如何用foreach遍历页面上所有的TextBox

评论 (0) All