繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- 编写通用的asp防注入程序
- vbs(asp)下的Function 语句
- ASP中类Class相关内容的整理资料
- 字符批量替换程序asp服务器版
- 旁注-网站小助手旭方修改免杀asp版
- 用正则表达式写的HTML分离函数
- asp中"无限流"分页程序代码
- asp的一个日期格式化函数
- asp中创建多级目录的两段代码
- asp中去除内容HTML标签的三个function函数
- chr(9)、chr(10)、chr(13)、chr(32)、chr(34)讲解
- 方便的大家admin及admin888 经过 md5加密后16位和32位代码
- 可用的ASP无重复数字随机函数, 数组实现, 并应用于随机显示记录集
- asp动态级联菜单代码
- ASP中经常使用的SQL语句与教程说明
- 实例分析之用ASP编程实现网络内容快速查找的代码
- 服务端 VBScript 与 JScript 几个相同特性的写法与示例
- ASP 环境下 VBS 事件应用 示例代码
- asp 之上传漏洞终结篇
- asp中一段防SQL注入的通用脚本
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 40 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
