繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- isNull(str), isEmpty(str)和 str = 的区别
- 使用ADO批量更新记录（源代码）
- 自己动手，结合javascript和dhtml做一个ubb编辑器
- 检查Email地址的比较完善的正则表达式函数
- 从Access数据库恢复BMP图像并显示在WEB页面(microsoft)
- ASP环境下邮件列表功能的实现 （四）（推荐）
- 在ASP应用中如何限制同一表单被多次提交！！！！好东西
- 了解MSMQ，控制ASP进程 （一）
- 了解MSMQ，控制ASP进程 （二）
- ASP技术在论坛中的运用(一)（吐血推荐！！！！）
- ASP技术在论坛中的运用(二)（吐血推荐！！！！）
- ASP技术在论坛中的运用(三)（吐血推荐！！！！）
- ASP技术在论坛中的运用(四)（吐血推荐！！！！）
- ASP技术在论坛中的运用(五)（吐血推荐！！！！）
- ASP技术在论坛中的运用(六)（吐血推荐！！！！）
- ASP技术在论坛中的运用(七)（吐血推荐！！！！）
- ASP技术在论坛中的运用(八)（吐血推荐！！！！）
- 不用数据源打开数据库（DSNless connection)
- 大部分的ADO的错误码对应的含义
- 好东西，翻页程序，大家可以参考
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 143 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
