繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp下制做行背景颜色交替变换的表格
- ASP
- 介绍一下GETROWS的用法
- 一个在vbscript中读取cookie的程序函数
- 用err.raise自定义错误信息
- 一段返回随机记录的代码
- 基于ACCESS数据库的纯asp论坛制作心得
- 不用Golobal.asa和session实现在线人数统计
- 在ASP里建表
- 结束ADOVB.INC的办法
- 存储过程分页
- 友情连接浏览器
- 怎样使用ASP实现Ping
- 用ASP读取Windows标准INI格式文件
- 使用ActiveX控件开发网页常见的问题
- 两个获取http页面的c#函数
- 将html源代码规范化，转换成XSL代码的asp工具
- 已调试好的asp程序在VB中转换为组件的技巧
- 关于如何动态地在同一页面实现两个互传
- 关于图片与文本同存在数据库中的具体思路
- 实现分页的例子-使用存储过程来实现分页
- 使用索引服务器- 使用索引服务器的对象
ASP 中的 asp下制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 223 ::
收藏到网摘: n/a
<%
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
