繁體中文当前位置: 首页 > 图文教程 > 脚本技术 > VBScript > 用vbscript脚本实现返回 IP 配置数据的代码
- VBScript
- 利用vbs脚本实现设置IE的打印页眉页脚信息
- 两个vbs脚本利用了wscirpt.network
- 一次载入2个vbs脚本的方法
- 一个可以更换windows xp or 2003的序列号的vbs脚本
- 利用VBS脚本自动创建计算机帐户的代码
- 利用VBS脚本轻松盗U盘数据
- 脚本-学习VBS的一个不错的教程
- 什么是 WSH(脚本宿主)的详细解释
- WSH 5.6(脚本宿主) 的新增功能
- 雷客图ASP站长安全助手vbs测试版代码
- ntiIframe.vbs用于批量清除被添加到文件中的恶意代码
- 用vbs控制iis创建虚拟目录的代码
- vbscript自动配置IIS的代码
- 使用ADSI、ASP和一对魔术戏法自动地创立一个虚拟目录的方法
- 妙用VBScript自制IE工具栏按钮的代码
- 利用vbs类实现css按钮的代码
- VBS中转换二进制数据为字符串常用办法
- 提供个可以显示农历的VBS代码
- 在一个vbs中包含其他vbs文件的方法
- 用vbs实现定时运行web文件的方法
VBScript 中的 用vbscript脚本实现返回 IP 配置数据的代码
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-11 浏览: 51 ::
收藏到网摘: n/a
用以返回配置数据（类似于 IPCONFIG 命令返回信息）的 WMI 脚本。
' Returning IP Configuration Data
' WMI script that returns configuration data similar to that returned by IpConfig.
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\"& strComputer & "\root\cimv2")
Set colAdapters = objWMIService.ExecQuery _
("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
n = 1
WScript.Echo
For Each objAdapter in colAdapters
WScript.Echo "Network Adapter " & n
WScript.Echo "================="
WScript.Echo " Description: " & objAdapter.Description
WScript.Echo " Physical (MAC) address: " & objAdapter.MACAddress
WScript.Echo " Host name: " & objAdapter.DNSHostName
If Not IsNull(objAdapter.IPAddress) Then
For i = 0 To UBound(objAdapter.IPAddress)
WScript.Echo " IP address: " & objAdapter.IPAddress(i)
Next
End If
If Not IsNull(objAdapter.IPSubnet) Then
For i = 0 To UBound(objAdapter.IPSubnet)
WScript.Echo " Subnet: " & objAdapter.IPSubnet(i)
Next
End If
If Not IsNull(objAdapter.DefaultIPGateway) Then
For i = 0 To UBound(objAdapter.DefaultIPGateway)
WScript.Echo " Default gateway: " & objAdapter.DefaultIPGateway(i)
Next
End If
WScript.Echo
WScript.Echo " DNS"
WScript.Echo " ---"
WScript.Echo " DNS servers in search order:"
If Not IsNull(objAdapter.DNSServerSearchOrder) Then
For i = 0 To UBound(objAdapter.DNSServerSearchOrder)
WScript.Echo " " & objAdapter.DNSServerSearchOrder(i)
Next
End If
WScript.Echo " DNS domain: " & objAdapter.DNSDomain
If Not IsNull(objAdapter.DNSDomainSuffixSearchOrder) Then
For i = 0 To UBound(objAdapter.DNSDomainSuffixSearchOrder)
WScript.Echo " DNS suffix search list: " & objAdapter.DNSDomainSuffixSearchOrder(i)
Next
End If
WScript.Echo
WScript.Echo " DHCP"
WScript.Echo " ----"
WScript.Echo " DHCP enabled: " & objAdapter.DHCPEnabled
WScript.Echo " DHCP server: " & objAdapter.DHCPServer
If Not IsNull(objAdapter.DHCPLeaseObtained) Then
utcLeaseObtained = objAdapter.DHCPLeaseObtained
strLeaseObtained = WMIDateStringToDate(utcLeaseObtained)
Else
strLeaseObtained = ""
End If
WScript.Echo " DHCP lease obtained: " & strLeaseObtained
If Not IsNull(objAdapter.DHCPLeaseExpires) Then
utcLeaseExpires = objAdapter.DHCPLeaseExpires
strLeaseExpires = WMIDateStringToDate(utcLeaseExpires)
Else
strLeaseExpires = ""
End If
WScript.Echo " DHCP lease expires: " & strLeaseExpires
WScript.Echo
WScript.Echo " WINS"
WScript.Echo " ----"
WScript.Echo " Primary WINS server: " & objAdapter.WINSPrimaryServer
WScript.Echo " Secondary WINS server: " & objAdapter.WINSSecondaryServer
WScript.Echo
n = n + 1
Next
Function WMIDateStringToDate(utcDate)
WMIDateStringToDate = CDate(Mid(utcDate, 5, 2) & "/" & _
Mid(utcDate, 7, 2) & "/" & _
Left(utcDate, 4) & " " & _
Mid (utcDate, 9, 2) & ":" & _
Mid(utcDate, 11, 2) & ":" & _
Mid(utcDate, 13, 2))
End Function
评论 (0) All
