繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP操作XML文件的完整实例
- ASP
- 用ASP编写图片计数器
- 最简洁的多重查询的解决方案
- 披着羊皮的大野狼 ASP中Session技巧
- 简单入门ASP变量
- 简单入门ASP子程序
- 几款Access 在线管理工具（ASP）比较
- ASP实例教程：Form集合
- ASP实例教程：FileSystemObject对象
- 关于ASP Recordset 分页出现负数解决方法及建议
- sdcms添加在线提交功能
- 如何配置IIS既可以运行ASP又可以运行PHP
- Asp获取当日文章并支持前一天后一天的方法
- ASP动态include文件
- 用ASP开发网页需要牢记的注意事项
- 利用ASP发送和接收XML数据的处理方法
- Session对象失效的客户端解决方法
- 通过数组给您的文件排序
- 一次性下载远程页面上的所有内容
- ASP生成不重复随机数字的另类思路
- asp模板引擎终结者(WEB开发之ASP模式)
ASP操作XML文件的完整实例
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 107 ::
收藏到网摘: n/a
<%
'----------------------------------------------------------------
'程序简介: 完成asp语言对XML文档中指定节点文本的增加、删除、修改、查看
'入口参数: 无
'出口参数: 无
'------------------------------------------------
'函数名字：ConnectXml()
'入口参数: filename 需要连接或打开的xml文件名
'出口参数: 无
'返回值 ：ConnectXml=0，XMLMorntekDocument就是一个成功装载XML文档的对象了。
' ConnectXml<>0,则打印错误信息strError
'------------------------------------------------
dim XMLMorntekDocument
function ConnectXml(filename)
dim strSourceFile
strSourceFile = Server.MapPath(filename)
Set XMLMorntekDocument = Server.CreateObject("Microsoft.XMLDOM")
XMLMorntekDocument.async = false
XMLMorntekDocument.load(strSourceFile)
ConnectXml=XMLMorntekDocument.parseerror.errorcode
if XMLMorntekDocument.parseerror.errorcode<>0 then
strError="<h2>error"&XMLMorntekDocument.parseerror.errorcode&"</h2>"
strError=strError&XMLMorntekDocument.parseerror.reason&"<br>"
strError=strError&XMLMorntekDocument.parseerror.url&"<br>"
strError=strError&XMLMorntekDocument.parseerror.line&"<br>"
strError=strError&XMLMorntekDocument.parseerror.filepos&"<br>"
strError=strError&XMLMorntekDocument.parseerror.srcText&"<br>"
response.write strError
end if
end function
'------------------------------------------------
'函数名字：CloseXml()
'入口参数: 无
'出口参数: 无
'------------------------------------------------
function CloseXml(XMLMorntekDocument)
if IsObject(XMLMorntekDocument) then
set XMLMorntekDocument=nothing
end if
end function
'------------------------------------------------
'函数名字：SelectXmlNodeText(elementname)
'入口参数: elementname 元素的名字
'出口参数: 无
'------------------------------------------------
function SelectXmlNodeText(elementname)
elementname="//"&elementname
temp=XMLMorntekDocument.selectSingleNode(elementname).text
selectXmlNodeText= server.htmlencode(temp)
end function
'------------------------------------------------
'函数名字：InsertXmlNodeText(befelementname,elementname,elementtext)
'入口参数: elementname 插入的元素的名字
' befelementname在此元素的名字前面插入元素
' elementtext 插入的元素的文本
'出口参数: 无
'------------------------------------------------
function InsertXmlNodeText(befelementname,elementname,elementtext)
dim befelement,element
set befelement=XMLMorntekDocument.selectSingleNode("//"&befelementname)
set element= XMLMorntekDocument.createelement(elementname)
befelement.insertBefore element,befelement.firstchild
element.text=elementtext
end function
'------------------------------------------------
'函数名字：UpdateXmlNodeText(elementname,newelementtext)
'入口参数: elementname 元素的名字
' newelementtext元素的新文本
'出口参数: 无
'------------------------------------------------
function UpdateXmlNodeText(elementname,newelementtext)
dim element
set element=XMLMorntekDocument.selectSingleNode("//"&elementname)
element.text=newelementtext
end function
'------------------------------------------------
'函数名字：DeleteXmlNodeText(elementname)
'入口参数: elementname 元素的名字
'出口参数: 无
'------------------------------------------------
function DeleteXmlNodeText(elementname)
XMLMorntekDocument.selectSingleNode("//"&elementname).text =""
end function
%>
评论 (0) All
