(1)    创建一个内容页面
我们已经使用Content Linking组件为本章提供的示例创建了菜单页面。Chapter06文件夹中的页面Default.htm采用上述代码创建菜单，如图6-2所示：

图6-2  使用Content Linking组件创建的菜单页面
       可以看到内容链接列表文件的内容显示在链接的下面，我们使用FileSystemObject对象完成这一工作。
       <%
       'create an instance of a FileSystemObject object
       Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

       'open the text file as a TextStream object
       Set objTStream = objFSO.OpenTextFile(Server.MapPath("contlink.txt"), ForReading)
       Response.Write objTStream.ReadAll                          'read the whole file and put into page
       ObjTStream.Close
       %>
       如果你编辑了contlink.txt文件，下次再次调用这个页面时，会看到菜单的条目发生了变化。注意文件中的最后三个条目，这三个条目使用前面介绍的redirect.asp技术，把绝对（而不是相对）的URL插入到列表中。
(2)    浏览这些页面
创建一个Content Linking组件实例并且使用它的一个方法时，将把当前页面的URL与指定的内容链接列表文件中的条目相匹配。不仅能用该组件创建一个内容列表（就像刚看到的那样），而且当在浏览器上打开其中一个页面时，可以用该组件对列表中的各个页面进行导航。
这意味着可以用超链接或按钮从这些页面中的一个移到另一个。例如，可以给页面添加Next和Back按钮，通过使用GetNextURL和GetPreviousURL方法能知道列表中的哪一个页面是前一个，哪一个页面是下一个。另一方面，能用GetNthURL方法跳到列表中的任何页面，用GetListIndex方法能知道当前页面在列表中的位置。
下面是一段给页面添加Next和Back按钮的代码，我们要做的只是把这段程序放在内容链接文件所列出的每一页中，或者用SSI的#include指令将它插入其中。
<!-- need a form to force Navigator to display the buttons -->
<FORM ACTION="">
<%
'we'll insert this into each page using an SSI #include statement
'create an instance of the Content Linking component
Set objNextLink = Server.CreateObject("MSWC.NextLink")
'set the content linking list file path and name
strListFile = "contlink.txt"
'get the index of the current page in the list
intThisPage = objNextLink.GetListIndex(strListFile)
If intThisPage > 1 Then  'can go back
%>
  <INPUT TYPE=BUTTON VALUE="< Back"
     ONCLICK="location.href='<% = objNextLink.GetPreviousURL(strListFile) %>';"
     TITLE="Go to '<% = objNextLink.GetPreviousDescription(strListFile) %>'">
  &nbsp;
<%
End If
%>
<INPUT TYPE=BUTTON VALUE=" Menu " ONCLICK="location.href='Default.asp';"
       TITLE="Return to the main 'Installable Components' menu">
<%
If intThisPage < objNextLink.GetListCount(strListFile) Then  'can go forward
%>
  &nbsp;
  <INPUT TYPE=BUTTON VALUE="Next >"
         ONCLICK="location.href='<%= objNextLink.GetNextURL(strListFile) %>';"
         TITLE="Go to '<% = objNextLink.GetNextDescription(strListFile) %>'">
<%
End If
%>
</FORM>
第一步是创建Content Linking组件，然后把列表文件名存入一个变量中，以便后面在创建页面里的客户端JScript代码时能够使用这个列表文件。另外这样做也便于页面的维护，因为如果想使用一个不同文件名仅需在一

评论 (0) All

登陆 还没注册？