当前位置: 首页 > 图文教程 > 网络编程 > ASP > 在ASP中使用断开的记录集

ASP
一段ASP 伪静态代码
asp的程序能实现伪静态化的方法
实例讲解实现抓取网上房产信息的ASP程序
[图]Flash+ASP实现电子互动地图在线标注功能
asp下多个域名后缀同时查询的域名查询系统
用ASP实现对ORACLE数据库的操作
用ASP做的DNS LOOKUP程序
用存储过程、GetRows()、抽取10万条数据的速度测试
asp中利用CSW中文分词组件来实现自己网站的内容关键词自动提取
ASP+JS三级联动下拉菜单[调用数据库数据]
用ASP实现距指定日期的倒记时程序源码
详细讲解ASP脚本循环语句
ASP中如何判断一个字符是不是汉字
将ACCESS转化成SQL2000要注意的问题
Microsoft JET Database Engine 错误 ''80004005'' 未指定的错误的完美解决方法
在ASP中使用均速分页法提高分页速度的方法
ASP+COM不得不注意的问题
ASP生成动态flash的工具与介绍
用asp实现的数据库中存取文件的代码
asp的通用数据分页类

No. « 55 56 57 58 »

技术文章搜索

关键字

在ASP中使用断开的记录集

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-11-03   浏览: 185 ::
收藏到网摘: n/a

       我们在使用ASP 内置的ADO组件进行数据库编程时，通常是在脚本的开头打开一个连接，并在脚本的最后关闭它，但是就较大脚本而言，在多数情况下连接打开的时间要比它需要打开的时间长得多。因此为了节省服务器资源，应该尽可能关闭连接以释放连接所占有的资源，这种关闭记录集的连接而不关闭记录集的技术叫做断开记录集，这个记录集本身则称为断开的记录集。
  
  　　下面我们就通过一个实例来说明这种技术的使用方法(NorthWind.mdb是Microsoft Access97自带的一个数据库，文件adovbs.inc可在C:\Program Files\Common Files\System\ADO下找到)：
  
  <% @LANGUAGE = VBScript %>
  
  <!--#include file="adovbs.inc"-->
  
  <%
  
  Response.Expires = 0
  
  Dim Cnn,objRS, strOut, strQ, strC
  
  
  StrC= "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("\asp24")
  
  & "\NorthWind.mdb;"
  
  '建立连接
  
  Set Cnn = Server.CreateObject("ADODB.Connection")
  
  Cnn.Open StrC
  
  
  '创建Recordset对象
  
  Set objRS = Server.CreateObject("ADODB.Recordset")
  
  objRS.CursorLocation =adUseClient
  
  objRS.CursorType = adOpenStatic
  
  objRS.LockType = adLockOptimistic
  
  
  strQ = "SELECT 运货商ID, 公司名称, 电话 FROM 运货商 "
  
  objRS.Open strQ, Cnn, , , adCmdText
  
  Set objRS.ActiveConnection = Nothing　　 '断开记录集
  
  
  Cnn.Close　　　　　　　　　　　　　　　　 '关闭连接
  
  Set Cnn = Nothing
  
  
  Response.Write "<HTML><BODY>"
  
  '下面使用断开的记录集
  
  Do While (Not objRS.EOF)
  
  strOut = objRS("运货商ID") & ", " & objRS("公司名称") & ", " & objRS("电话")
  
  Response.Write Server.HTMLEncode(strOut) & "<BR>"
  
  objRS.MoveNext
  
  Loop
  
  Response.Write "<BR>准备新增或插入记录: "
  
  
  '若需要更新数据库, 则要重新建立连接
  
  Set Cnn = Server.CreateObject("ADODB.Connection")
  
  Cnn.Open strC
  
  Set objRS.ActiveConnection = Cnn
  
  
  objRS.Filter = "公司名称 = '吴丰'"
  
  If objRS.EOF Then
  
  objRS.AddNew
  
  objRS("公司名称") = "吴丰"
  
  objRS("电话") = "571-7227298"
  
  objRS.Update
  
  Response.Write "符合该条件的记录不存在, 则新增.<BR>"
  
  Else
  
  objRS("电话") = "571-7227071"
  
  Response.Write "符合该条件的记录存在, 则 Update.<BR>"
  
  objRS.Update
  
  End If
  
  
  Set objRS.ActiveConnection = Nothing
  
  Cnn.close
  
  Set Cnn = Nothing
  
  objRS.Close
  
  Set objRS = Nothing
  
  
  Response.Write "</BODY></HTML>"
  
  %>