繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 在ASP中使用断开的记录集
- ASP
- 自动清空站点目录下所有文件
- ASPEMAIL通过Mdaemon的SMTP发信－recipient unknow处理办法
- 使用split分割多字符的字符串的方法
- ASP调用oracle存储过程
- ASP访问INTERBASE数据库
- 利用Session限制重复操作的简单方法
- 一个socket组件及其调用方法
- ASP模仿asp.net的DataGrid
- 利用ASP技术实现文件直接上传功能
- 微软建议的ASP性能优化28条守则
- 温柔的杀手—跨站ASP Script攻击
- aspjpeg组件高级使用方法介绍
- asp+sqlserver 分页方法（不用存储过程）
- Windows 2003上传文件不能超过200k解决方法
- 一个比较实用的asp函数集合类
- WebClasses使注册变得容易
- ASP对FoxPro自由表(DBF文件)的操作
- HTTP_REFERER的工作方式
- 抓取动网论坛Email地址的一段代码
- ASP+FSO+框架实现ASP生成htm并分页的方法(批量)
在ASP中使用断开的记录集
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 139 ::
收藏到网摘: n/a
下面我们就通过一个实例来说明这种技术的使用方法(NorthWind.mdb是Microsoft Access97自带的一个数据库，文件adovbs.inc可在C:\Program Files\Common Files\System\ADO下找到)：
<% @LANGUAGE = VBScript %>
<!--#include file="adovbs.inc"-->
<%
Response.Expires = 0
Dim Cnn,objRS, strOut, strQ, strC
StrC= "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("\asp24")
& "\NorthWind.mdb;"
'建立连接
Set Cnn = Server.CreateObject("ADODB.Connection")
Cnn.Open StrC
'创建Recordset对象
Set objRS = Server.CreateObject("ADODB.Recordset")
objRS.CursorLocation =adUseClient
objRS.CursorType = adOpenStatic
objRS.LockType = adLockOptimistic
strQ = "SELECT 运货商ID, 公司名称, 电话 FROM 运货商 "
objRS.Open strQ, Cnn, , , adCmdText
Set objRS.ActiveConnection = Nothing '断开记录集
Cnn.Close '关闭连接
Set Cnn = Nothing
Response.Write "<HTML><BODY>"
'下面使用断开的记录集
Do While (Not objRS.EOF)
strOut = objRS("运货商ID") & ", " & objRS("公司名称") & ", " & objRS("电话")
Response.Write Server.HTMLEncode(strOut) & "<BR>"
objRS.MoveNext
Loop
Response.Write "<BR>准备新增或插入记录: "
'若需要更新数据库, 则要重新建立连接
Set Cnn = Server.CreateObject("ADODB.Connection")
Cnn.Open strC
Set objRS.ActiveConnection = Cnn
objRS.Filter = "公司名称 = '吴丰'"
If objRS.EOF Then
objRS.AddNew
objRS("公司名称") = "吴丰"
objRS("电话") = "571-7227298"
objRS.Update
Response.Write "符合该条件的记录不存在, 则新增.<BR>"
Else
objRS("电话") = "571-7227071"
Response.Write "符合该条件的记录存在, 则 Update.<BR>"
objRS.Update
End If
Set objRS.ActiveConnection = Nothing
Cnn.close
Set Cnn = Nothing
objRS.Close
Set objRS = Nothing
Response.Write "</BODY></HTML>"
%>
评论 (0) All
