要做一名好的小偷有点难度:P
  
  这是我投给电脑报的一篇稿子,很简单,写得很仓促,有很多不足的地方,高手们笑的时候麻烦指正一下,原文是拿ALEXA开刀,我在落伍发表的时候修改成了QQ天气预报小偷.
  
  灵活运用XMLHTTP组件
  
  你也可以做“小偷”
  
   看到这个标题你可千万别误会，这里所说的“小偷”指的是在ASP中运用XML中的XMLHTTP组件提供的强大功能，把远程网站上的数据（图片，网页及其他文件）抓取到本地，经过各种处理后显示到页面上或者存储进数据库的一类程序。你可以通过这种小偷程序，完成过去一些似乎完全不可能实现的任务，比如说把某个站的页面偷梁换柱后变成自己的页面，或者把某个站的一些数据（文章，图片）保存到本地数据库中加以利用。“小偷”的优点有：无须维护网站，因为小偷程序中的数据来自其他网站，它将随着该网站的更新而更新；可以节省大量的服务器资源，一般小偷程序就几个文件，所有网页内容都是来自其他网站。缺点在于：不稳定，如果目标网站出错，程序也会出错，而且，如果目标网站进行升级维护，那么小偷程序也要进行相应修改；速度，因为是远程调用，速度和在本地服务器上读取数据比起来，肯定要慢一些。怎么样，听起来很神奇吧？我们现在就开始来学习一些“小偷”程序的入门知识吧！
  
  我们拿个简单点的东西来研究一下吧，QQ网站上的天气预报程序
  
  程序演示地址：http://www.gtocn.com/tianqi.asp
  源码下载：http://www.gtocn.com/tianqi.txt
  
  代码如下：
  
  <%
  On Error Resume Next
  Server.ScriptTimeOut=9999999
  Function getHTTPPage(Path)
   t = GetBody(Path)
   getHTTPPage=BytesToBstr(t,"GB2312")
  End function
  
  '首先，进行小偷程序的一些初始化设置，以上代码的作用分别是忽略掉所有非致命性错误，把小偷程序的运行超时时间设置得很长（这样不会出现运行超时的错误），转换原来默认的UTF-8编码转换成GB2312编码，否则直接用XMLHTTP组件调用有中文字符的网页得到的将是乱码。
  
  Function GetBody(url)
   on error resume next
   Set Retrieval = CreateObject("Microsoft.XMLHTTP")
   With Retrieval
   .Open "Get", url, False, "", ""
   .Send
   GetBody = .ResponseBody
   End With
   Set Retrieval = Nothing
  End Function
  
  '然后调用XMLHTTP组件创建一个对象并进行初始化设置。
  
  Function BytesToBstr(body,Cset)
   dim objstream
   set objstream = Server.CreateObject("adodb.stream")
   objstream.Type = 1
   objstream.Mode =3
   objstream.Open
   objstream.Write body
   objstream.Position = 0
   objstream.Type = 2
   objstream.Charset = Cset
   BytesToBstr = objstream.ReadText
   objstream.Close
   set objstream = nothing
  End Function
  
  Function Newstring(wstr,strng)
   Newstring=Instr(lcase(wstr),lcase(strng))
   if Newstring<=0 then Newstring=Len(wstr)
  End Function
  
  '处理抓取回来的数据需要调用adodb.stream组件并进行初始化设置。%>
  
  '以下即为页面显示部分
  
  <%
  Dim wstr,str,url,start,over,city
  '定义一些需要使用到的变量
  
  city = Request.QueryString("id")
  '程序传回的ID变量（即用户选择的城市）赋给id
  
  url="http://appnews.qq.com/cgi-bin/news_qq_search?city="&city&""
  '这里设置需要抓取的页面地址，当然你也可以直接指定某个地址而不使用变量
  
  wstr=getHTTPPage(url)
  '获取指定页面的全部数

评论 (0) All

登陆 还没注册？