繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 制做行背景颜色交替变换的表格
- ASP
- ASP实现不存在的网页就自动发送邮件
- 多个绑定多域名的ASP代码
- ASP导出Excel数据的四种方法
- 用控件的方式解决问题-在客户端关联WEB控件引用
- 用ASP建立一个简单的聊天室
- 用Asp隐藏文件路径,实现防盗链
- ASP实例：即时显示当前页面浏览人数
- 网页视频播放器程序代码通用代码
- Cookies 欺骗漏洞的防范(vbs+js 实现)
- ASP应用程序设计的Web状态管理分析
- ASP中Session技巧
- ASP教程：透彻掌握ASP分页技术
- ASP获取字符串长度的自定义函数
- 通过实例讲解来学习ASP中的函数
- ASP实例代码：长文章分页代码设置方法
- 深入理解ASP中FSO的神奇功能
- 用ASP代码得到客户端IP和当前地址
- 服务端 VBScript 与 JScript 几个相同特性的写法
- JS+DIV模拟SELECT表单域
- 插入ASP代码让网站数据库成为ASP木马
ASP 中的 制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 54 ::
收藏到网摘: n/a
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
