繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 制做行背景颜色交替变换的表格
- ASP
- 迁移到 ASP .NET：需考虑的重要问题(2)
- ASP中优化数据库处理
- 结合XML, ADO, 以及ASP
- 在ASP中优化数据库处理
- 提高ASP性能的最佳选择（一）
- 返回UPDATE SQL语句所影响的行数的方法
- ASP如何使用MYSQL数据库
- 安全维护 IIS asp 站点的高级技巧
- 也谈ASP中的RESPONSE属性
- ASP提速技巧
- 在ASP中如何访问Novell下的数据库
- 改善ASP性能和外观的技巧集锦（上）
- 改善ASP性能和外观的技巧集锦（中）
- 改善ASP性能和外观的技巧集锦（下）
- 利用ASP在浏览器上打印输出
- 用ASP文件实现CPU的使用率始终保持100％
- ASP 0115 Error的解决方案
- Varchar与char的区别
- 探讨一下rs(0)和rs(fieldname)的执行效率
- 连接WEB数据库的ADO性能提高技巧
ASP 中的 制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 201 ::
收藏到网摘: n/a
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
