繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 制做行背景颜色交替变换的表格
- ASP
- ASP漏洞及安全建议(3)
- ASP漏洞及安全建议(4)
- 实现聊天室的悄悄话功能（上）
- 实现聊天室的悄悄话功能（中）
- 用ＡＳＰ实现悄悄话的功能
- 《 优化你的ASP程序 》
- 让ASP应用系统成为跨平台的应用系统
- 让ASP应用系统成为跨平台的应用系统(2)
- 使用ASP加密算法加密你的数据（一）
- 使用ASP加密算法加密你的数据（二）
- 用ASP制作个性化的调查板
- asp+语法介绍（二）---书写我们的第一个asp+ 文件
- asp+语法介绍(一)
- asp+语法介绍(三)----asp+的服务器端编程初步
- asp+语法介绍(四)----asp+的服务器端编程进介
- asp+语法介绍(五)----asp+的服务器端编程控件篇
- sp+语法介绍(六)----数据库篇
- 用ASP和VBScript上载文件（一）
- 用ASP和VBScript上载文件（二）
- 解析正则表达式（原创）
ASP 中的 制做行背景颜色交替变换的表格
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 183 ::
收藏到网摘: n/a
Const adInteger = 3
Const adVarChar = 200
' 声明变量
Dim myRecordset
Dim iLetter
Dim Field
Dim strAltColor
Dim bColor
bColor = False
' 此例利用内存中的recordset,你需要做的只是修改你的数据显示的部分就可以了。
Set myRecordset = Server.CreateObject("ADODB.Recordset")
myRecordset.Fields.Append "ID", adInteger
myRecordset.Fields.Append "Title", adVarChar, 25
myRecordset.Fields.Append "Description", adVarChar, 255
myRecordset.Open
' Fill RS with sample data:
For iLetter = Asc("A") To Asc("M")
myRecordset.AddNew
myRecordset.Fields("ID").Value = iLetter - 64
myRecordset.Fields("Title").Value = "字母：" & Chr(iLetter)
myRecordset.Fields("Description").Value = "这里测试字母：" & Chr(iLetter) & "."
myRecordset.Update
Next 'iLetter
'移动到头部开始位置，以便下面的循环开始.
myRecordset.MoveFirst
' 在表格中显示数据
Response.Write "<table border=""0"" cellspacing=""0"" cellpadding=""3"">" & vbCrLf
'表头
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor=""#CCCCCC""><strong>"
Response.Write Field.Name
Response.Write "</strong></td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
Do While Not myRecordset.EOF
' 循环改变单元格的背景颜色
bColor = Not bColor
If bColor Then
strAltColor = "#FFFFFF"
Else
strAltColor = "#FF8040"
End If
'循环改变单元格的背景颜色
Response.Write vbTab & "<tr>" & vbCrLf
For Each Field in myRecordset.Fields
Response.Write vbTab & vbTab & "<td bgcolor="""
Response.Write strAltColor
Response.Write """>" & Field.Value & "</td>" & vbCrLf
Next 'Field
Response.Write vbTab & "</tr>" & vbCrLf
myRecordset.MoveNext
Loop
' End the table
Response.Write "</table>" & vbCrLf
' 关闭对象、释放资源
myRecordset.Close
Set myRecordset = Nothing
%>
评论 (0) All
