繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP.NET > 使用API函数复制文件，可显示进度。
- ASP.NET
- asp.net SqlParameter关于Like的传参数无效问题
- 数据库 数据类型float到C#类型decimal, float数据类型转化无效
- google suggest 下拉菜单实现代码(asp.net版本)
- asp.net(C#) 动态添加非ASP的标准html控件（如添加Script标签）
- asp.net GridView导出到Excel代码
- asp.net 开发的一些常用技巧
- php 三级联动菜单
- ASp.net 文本框（TextBox)计算,判断输入的是否是数字
- asp.net 存储过程调用
- asp.net 操作XML 按指定格式写入XML数据 WriteXml
- asp.net连接数据库 增加，修改，删除，查询代码
- VB.net 查询获取数据库数据信息
- asp.net 删除，更新数据库方法
- .net获取硬件信息_CPU序列号
- ASP.NET 页面中动态增加的控件、添加事件
- 彻底解决ASP.NET MD5加密中文结果和ASP不一致的问题
- asp.net结合aspnetpager使用SQL2005的存储过程分页
- asp.net 用户控件读取以及赋值
- asp.net 弹出警告窗口实现代码
- asp.net 枚举文件里面的数字绑定到DropDownList里面去
ASP.NET 中的 使用API函数复制文件，可显示进度。
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 217 ::
收藏到网摘: n/a
以前一直以为用API函数只能调用系统的那个复制的对话框来显示进度，原来还有其他方法可以用，不过这个API只能在NT4.0及以上的版本上面才有。
在工程里添加一个模块，将以下代码复制到模块里
Private Const PROGRESS_CANCEL = 1
Private Const PROGRESS_CONTINUE = 0
Private Const PROGRESS_QUIET = 3
Private Const PROGRESS_STOP = 2
Private Const COPY_FILE_FAIL_IF_EXISTS = &H1
Private Const COPY_FILE_RESTARTABLE = &H2
'// 此 API 在 WIN9X 下不能使用
Private Declare Function CopyFileEx Lib "kernel32.dll" Alias "CopyFileExA" (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal lpProgressRoutine As Long, lpData As Any, ByRef pbCancel As Long, ByVal dwCopyFlags As Long) As Long
Private mlngCancel As Long
Private mprgState As Object
Private mlblState As Object
Public Function CopyProgressRoutine(ByVal TotalFileSize As Currency, _
ByVal TotalBytesTransferred As Currency, _
ByVal StreamSize As Currency, _
ByVal StreamBytesTransferred As Currency, _
ByVal dwStreamNumber As Long, _
ByVal dwCallbackReason As Long, _
ByVal hSourceFile As Long, _
ByVal hDestinationFile As Long, _
ByVal lpData As Long) As Long
'// 显示进度
mprgState.Value = CLng((100 / TotalFileSize) * TotalBytesTransferred)
mlblState.Caption = "已完成: " & FormatPercent(mprgState.Value / 100, 0)
'
DoEvents
'// 继续复制
CopyProgressRoutine = PROGRESS_CONTINUE
End Function
'************************************************
'** 函数名称: uCopyFile
'** 函数功能: 复制文件
'** 参数说明:
'** strFrom 源文件
'** strTo 目标文件
'** prgState 进度条控件
'** lblState 用来显示进度的 Label
'** 函数返回:
'** Boolean 类型
'** True 复制成功
'** False 复制失败
'** 参考实例:
'**
'** blnReturn = uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)
'************************************************
Public Function uCopyFile(ByVal strFrom As String, _
ByVal strTo As String, _
ByRef prgState As Object, _
ByRef lblState As Object) As Boolean
Dim lngReturn As Long
Set mprgState = prgState
Set mlblState = lblState
'// 开始复制
lngReturn = CopyFileEx(strFrom, strTo, _
AddressOf CopyProgressRoutine, ByVal 0&, mlngCancel, COPY_FILE_RESTARTABLE)
If lngReturn = 0 Then
uCopyFile = False
Else
uCopyFile = True
End If
End Function
在调用时，直接使用 uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)，其中的 prgState 你可以去掉不要，由自己来定。
评论 (0) All
