繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP.NET > 使用API函数复制文件，可显示进度。
- ASP.NET
- asp.net下用服务器端代码解决浏览器兼容性问题
- asp.net 安全的截取指定长度的html或者ubb字符串
- asp.net 在线编辑word文档 可保存到服务器
- asp.net 提高网站速度及如何利用缓存
- asp.net 修改/删除站内目录操作后Session丢失问题
- asp.net URL重写简化版 速学URL重写
- asp.net EncryptHelper 加密帮助类
- asp.net JSONHelper JSON帮助类
- C# 调用存储过程简单完整的实例代码
- vs2008 安装失败的总结与分享
- HttpHandler HttpModule入门篇
- ASP.NET(AJAX+JSON)实现对象调用
- Asp.net 基于Cookie简易的权限判断
- asp.net通过HttpModule自动在Url地址上添加参数
- asp.net 字符串、二进制、编码数组转换函数
- ASP.NET操作Excel备忘录
- 记录游客页面访问IP的简易实现代码 (asp.net+txt)
- 比较简单的将数据信息导入wrod文档方案(C# for word)
- 增加asp.net应用程序性能的20种方法(简单有效)
- ASP.NET 图片防盗链的实现原理分析
ASP.NET 中的 使用API函数复制文件，可显示进度。
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 73 ::
收藏到网摘: n/a
以前一直以为用API函数只能调用系统的那个复制的对话框来显示进度，原来还有其他方法可以用，不过这个API只能在NT4.0及以上的版本上面才有。
在工程里添加一个模块，将以下代码复制到模块里
Private Const PROGRESS_CANCEL = 1
Private Const PROGRESS_CONTINUE = 0
Private Const PROGRESS_QUIET = 3
Private Const PROGRESS_STOP = 2
Private Const COPY_FILE_FAIL_IF_EXISTS = &H1
Private Const COPY_FILE_RESTARTABLE = &H2
'// 此 API 在 WIN9X 下不能使用
Private Declare Function CopyFileEx Lib "kernel32.dll" Alias "CopyFileExA" (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal lpProgressRoutine As Long, lpData As Any, ByRef pbCancel As Long, ByVal dwCopyFlags As Long) As Long
Private mlngCancel As Long
Private mprgState As Object
Private mlblState As Object
Public Function CopyProgressRoutine(ByVal TotalFileSize As Currency, _
ByVal TotalBytesTransferred As Currency, _
ByVal StreamSize As Currency, _
ByVal StreamBytesTransferred As Currency, _
ByVal dwStreamNumber As Long, _
ByVal dwCallbackReason As Long, _
ByVal hSourceFile As Long, _
ByVal hDestinationFile As Long, _
ByVal lpData As Long) As Long
'// 显示进度
mprgState.Value = CLng((100 / TotalFileSize) * TotalBytesTransferred)
mlblState.Caption = "已完成: " & FormatPercent(mprgState.Value / 100, 0)
'
DoEvents
'// 继续复制
CopyProgressRoutine = PROGRESS_CONTINUE
End Function
'************************************************
'** 函数名称: uCopyFile
'** 函数功能: 复制文件
'** 参数说明:
'** strFrom 源文件
'** strTo 目标文件
'** prgState 进度条控件
'** lblState 用来显示进度的 Label
'** 函数返回:
'** Boolean 类型
'** True 复制成功
'** False 复制失败
'** 参考实例:
'**
'** blnReturn = uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)
'************************************************
Public Function uCopyFile(ByVal strFrom As String, _
ByVal strTo As String, _
ByRef prgState As Object, _
ByRef lblState As Object) As Boolean
Dim lngReturn As Long
Set mprgState = prgState
Set mlblState = lblState
'// 开始复制
lngReturn = CopyFileEx(strFrom, strTo, _
AddressOf CopyProgressRoutine, ByVal 0&, mlngCancel, COPY_FILE_RESTARTABLE)
If lngReturn = 0 Then
uCopyFile = False
Else
uCopyFile = True
End If
End Function
在调用时，直接使用 uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)，其中的 prgState 你可以去掉不要，由自己来定。
评论 (0) All
