繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP.NET > 使用API函数复制文件，可显示进度。
- ASP.NET
- 调用另外一个同名的重载函数漏掉括号出现的严重问题
- DataGrid模板列应用：在DataGrid中用CheckBox控制TextBox的Enabled属性
- 使用存储过程的一个小例子
- .net中xmlhttp下载文件的方法参考
- 简单的c#文本文件读写
- 我的C#学习过程 第一天 安装
- 在数据库中开始一个事务。
- 用ASP.NETt实现简单的文字水印
- C/S系统中三层结构（Com/Com+）的测试成功实现
- VB 二进制块读写类模块应用实例，包括一个文件拷贝和一个文件二进制比较的例子。
- 扫雷程序“布雷”代码（vb）
- 关于网络连接状态的编程
- c#中ref和out参数使用时需要注意的问题
- use Assembly to call a method
- 在VBA中调用AUTOCAD打印文件
- 在VS.NET的
- 昨天折腾了一晚上，哪位高手帮我看看！急！
- Net是未来的趋势吗?
- 如何修改自定义Webpart 的标题(downmoon)
- [收藏]ASP.Net生成静态HTML页 选择自 coofucoo 的 Blog
ASP.NET 中的 使用API函数复制文件，可显示进度。
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-11-03 浏览: 102 ::
收藏到网摘: n/a
以前一直以为用API函数只能调用系统的那个复制的对话框来显示进度，原来还有其他方法可以用，不过这个API只能在NT4.0及以上的版本上面才有。
在工程里添加一个模块，将以下代码复制到模块里
Private Const PROGRESS_CANCEL = 1
Private Const PROGRESS_CONTINUE = 0
Private Const PROGRESS_QUIET = 3
Private Const PROGRESS_STOP = 2
Private Const COPY_FILE_FAIL_IF_EXISTS = &H1
Private Const COPY_FILE_RESTARTABLE = &H2
'// 此 API 在 WIN9X 下不能使用
Private Declare Function CopyFileEx Lib "kernel32.dll" Alias "CopyFileExA" (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal lpProgressRoutine As Long, lpData As Any, ByRef pbCancel As Long, ByVal dwCopyFlags As Long) As Long
Private mlngCancel As Long
Private mprgState As Object
Private mlblState As Object
Public Function CopyProgressRoutine(ByVal TotalFileSize As Currency, _
ByVal TotalBytesTransferred As Currency, _
ByVal StreamSize As Currency, _
ByVal StreamBytesTransferred As Currency, _
ByVal dwStreamNumber As Long, _
ByVal dwCallbackReason As Long, _
ByVal hSourceFile As Long, _
ByVal hDestinationFile As Long, _
ByVal lpData As Long) As Long
'// 显示进度
mprgState.Value = CLng((100 / TotalFileSize) * TotalBytesTransferred)
mlblState.Caption = "已完成: " & FormatPercent(mprgState.Value / 100, 0)
'
DoEvents
'// 继续复制
CopyProgressRoutine = PROGRESS_CONTINUE
End Function
'************************************************
'** 函数名称: uCopyFile
'** 函数功能: 复制文件
'** 参数说明:
'** strFrom 源文件
'** strTo 目标文件
'** prgState 进度条控件
'** lblState 用来显示进度的 Label
'** 函数返回:
'** Boolean 类型
'** True 复制成功
'** False 复制失败
'** 参考实例:
'**
'** blnReturn = uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)
'************************************************
Public Function uCopyFile(ByVal strFrom As String, _
ByVal strTo As String, _
ByRef prgState As Object, _
ByRef lblState As Object) As Boolean
Dim lngReturn As Long
Set mprgState = prgState
Set mlblState = lblState
'// 开始复制
lngReturn = CopyFileEx(strFrom, strTo, _
AddressOf CopyProgressRoutine, ByVal 0&, mlngCancel, COPY_FILE_RESTARTABLE)
If lngReturn = 0 Then
uCopyFile = False
Else
uCopyFile = True
End If
End Function
在调用时，直接使用 uCopyFile("c:\test.exe", "d:\test.exe", prgState, lblState)，其中的 prgState 你可以去掉不要，由自己来定。
评论 (0) All
