当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP 三层架构 Error处理类

ASP
提高SQL的执行效率的ASP的五种做法
asp的offset的一个go to page
asp中command的在单条记录时,有些字段显示为空的问题
asp,php一句话木马整理方便查找木马
asp 合并记录集并删除的sql语句
asp下循环一行多少个
asp循环行数输出函数
asp access重新开始编号
ASP生成数字相加求和的BMP图片验证码
静态页面利用JS读取cookies记住用户信息
比较详细的Asp伪静态化方法及Asp静态化探讨
asp Response.flush 实时显示进度
Asp高级故障解决以及相关代码
asp智能脏话过滤系统v1.0
ASP文件中的安全问题
Access数据库中“所有记录中均未找到搜索关键字”的解决方法
asp两组字符串数据比较合并相同数据
asp MYSQL出现问号乱码的解决方法
asp文章中随机插入网站版权文字的实现代码
ASP利用XMLHTTP实现表单提交以及cookies的发送的代码

No. « 77 78 79 80 »

技术文章搜索

关键字

ASP 三层架构 Error处理类

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-10-12   浏览: 113 ::
收藏到网摘: n/a

看到有朋友说前面一章讲得没必要,想想也确实.本来是没有打算讲这些基础的,只是行文起来没有约束,就荡开到基础知识上面了. 从这节开始,将会给大家介绍几个ASP中的三大通用类,它贯穿于我所设计的三层架构中,是对ASP语法的扩展,可以提高很多细节处理上的效率,可以算是一点点框架的味道.
本节介绍错误处理类,类名Con_Error,在代码页面之初就进行初始化,实例名为e,以下的e.add 即使用该错误类的实例化对象进行操作.
方法介绍:
e.Add(ByVal vErrorMessage ) 记录一个错误,并且设置 e.Error = true . 在程序检测用户名合法性等地方发现错误时,就调用这个方法,记录一个错误信息.
例如,用户登陆时密码错误,则调用 e.add("您的账号或密码错误") .这时候,错误对象e中便记录了一个错误,错误对象的属性e.Error=true .在后续操作中,可以使用错误对象的这个属性进行判断.
例如:
出现错误后弹出小窗口提示错误,并返回前一页.
if e.Error then
e.Alert_Back "请重新登录!" 'Alert_Back 的作用在后面介绍.
end if
e.Alert_Back(ByVal vMessage) 使用Javascript弹出一个错误提示框,显示目前所有的错误列表,Alert_Back(vMessage)中的vMessage显示在最后一行,用于提示用户在看到这个错误信息后需要采取的步骤. 并且返回到前一页. 这个方法的代码贴出来,大家会更好理解:
Public Sub Alert_Back(ByVal vMessage)
strJSMessage = JSMessage & vMessage 'JSMessage用于存储e对象中的错误列表,每个错误之间用\n分开.
%>
<script language="javascript" >
<!--//
alert("<%=strJSMessage %>"); '弹出提示错误框.
history.back(); '返回前一页
//-->
</script>
<%
response.end '注意这里要停止输出,避免出错的同时程序还继续执行.
End Sub
e.Alert_Back 方法延伸了几个类似效果的方法,如下一同介绍,实现的过程请看附加的源码:
e.Alert(ByVal vMessage) 只弹出错误提示框,不返回前一页,也不停止程序的执行.
e.Alert_Close(ByVal vMessage) 弹出错误提示框,当用户点击确定后,关闭当前窗口
e.OK_Go(ByVal vMessage,ByVal vURL) 弹出信息提示框,当用户点击确定后,跳转到vURL页面
e.Go(ByVal vURL) 直接跳转到vURL页面
以上几个方法的作用,大家应该都很熟悉了,其实它们不仅限于错误处理的.
e.Clear 清空错误对象中记录的错误信息 , e.Error = false
因为e对象是一个全局的对象,可能在很多过程中都调用了. 当你只需要统计某一个模块中的错误时,可以在开始调用这个方法,清空e中的错误.
以下几个是对Response.Write的包装,目的仅仅是为了使用时的方便快速.
e.Debug(ByVal vMessage) 输出调试信息. 当程序完工时,其中会存在不少用Response.write 输出的错误调试信息,要都删掉又要细细地找. 使用e.Debug专门输出调试信息,当程序完成时,只需要搜索e.Debug,就可以找到所有的调试错误信息的位置.
e.w(ByVal vMessage) 输出信息. 仅仅是Response.write的简单包装,在程序中输入e.w 比输入Response.write 不知道要方便多少,而且总是容易写错.
e.BR 输出一个换行符,等同于 response.Write "<BR />"
以下4个是对Response.End的包装,只是按照操作习惯,定义的几个一样功能的方法:
e.Pause == Response.End
e.P == Response.End
e.Stop == Response.End
e.End == Response.End
还有一个属性e.Message ,输出e对象中所有的错误列表
具体的实现细节请看代码
复制代码 代码如下:

Class Con_Error
Private blnError
private strMessage
private strJSMessage
Private Sub Class_initialize()
blnError = false
strMessage = ""
End Sub
Private Sub Class_Terminate()
End Sub
' ==================================================================================
' Property
' ==================================================================================
' Message :
Public Property Let Message(ByVal value)
strMessage = value
End Property
Public Property Get Message()
Message = strMessage
End Property
' Error number
Public Property Get Error()
Error = blnError
End Property
' JSMessage : show in messagebox
Private Property Get JSMessage()
strJSMessage = Replace(strMessage , "<br>" , "\n")
strJSMessage = Replace(strJSMessage , vbCrLf , "")
JSMessage = strJSMessage
End Property
' ==================================================================================
' Method
' ==================================================================================
' Add : add an Error message
Public Sub Add(ByVal vMessage)
blnError = true
strMessage = strMessage & vMessage & "<br>"
End Sub
Public Sub Clear
blnError = false
strMessage = ""
End Sub
' Alert
Public Sub Alert(ByVal vMessage)
strJSMessage = JSMessage & vMessage
%>
<script language="javascript" >
<!--//
alert("<%=strJSMessage %>");
//-->
</script>
<%
End Sub
' Alert_Back : alert and back
Public Sub Alert_Back(ByVal vMessage)
strJSMessage = JSMessage & vMessage
%>
<script language="javascript" >
<!--//
alert("<%=strJSMessage %>");
history.back();
//-->
</script>
<%
response.end
End Sub
' Alert_Close : alert and close
Public Sub Alert_Close(ByVal vMessage)
strJSMessage = JSMessage & vMessage
%>
<script language="javascript" >
<!--//
alert("<%=strJSMessage %>");
window.opener = null;
window.close();
//-->
</script>
<%
response.end
End Sub
'*********************************************
'Debug : response.write ,use it to delete debug message easily,just seach "e.Debug" from files
'*********************************************
Public Sub OK_Go(ByVal vMessage,ByVal vURL)
strJSMessage = JSMessage & vMessage
%>
<script language="javascript" >
<!--//
alert("<%=strJSMessage %>");
location.href = '<%=vURL %>';
//-->
</script>
<%
response.end
End Sub
Public Sub Go(ByVal vURL)
response.Redirect vURL
response.end
End Sub
'*********************************************
'Debug : response.write ,use it to delete debug message easily,just seach "e.Debug" from files
'*********************************************
Public Sub Debug (ByVal vMessage)
response.Write vMessage
response.flush
End Sub
' ****** W : write
Public Sub W(ByVal vMessage)
response.Write vMessage
End Sub
' ****** BR : write <br>
Public Sub Br
response.Write "<BR />"
End Sub
'*********************************************
'Pause : response.end , mark debug info clearly
'*********************************************
Public Sub Pause
response.end
End Sub
Public Sub P
response.end
End Sub
Public Sub [Stop]
response.end
End Sub
Public Sub [end]
response.end
End Sub
End Class