繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 在ASP中限制同一表单被多次提交
- ASP
- ASP动态生成的javascript表单验证代码
- 将身份证从15位升级为18位的函数
- ASP自定义函数，仿VBA中域函数DLookup
- 6行代码实现无组件上传
- 用VS2003调试ASP的方法和体会
- ASP中存储过程调用的两种方式及比较
- 升级到2003后访问数据库发生8007007f错误的解决
- ACCESS转化成SQL2000需要注意的几个问题
- 让ASP程序运行于非Windows平台
- 一些不长见的ASP调用存储过程的技巧
- 网站图片扫描类
- 一条sql 语句搞定数据库分页
- 在ASP中取得服务器网卡的MAC地址、DNS地址等网络信息
- ASP中轻松实现变量名－值变换
- 用Xml2OleDb将XML文件插入到数据库
- 购物车中数据的存放方式
- ASP数据库编程SQL常用技巧
- 在ASP中利用ADO显示Excel文件内容的函数
- ASP+SQL Server之图象数据处理
- 在 Access 中使用“存储过程”
在ASP中限制同一表单被多次提交
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-08-14 浏览: 167 ::
收藏到网摘: n/a
本文介绍在ASP应用中防止用户在当前会话期间多次提交同一表单的一个简单方法。它主要由四个子程序组成，在较为简单的应用场合，你只要将这些代码放在包含文件中直接引用即可；对于那些较为复杂的环境，我们在文章的最后给出一些改进建议。
一、基本工作过程
下面我们依次讨论这四个子程序。
（一）初始化
这里我们要在Session对象中保存两个变量，其中：
⑴ 每一个表单对应一个称为FID的唯一标识，为使该值唯一要用到一个计数器。
⑵ 每当一个表单成功提交，必须在一个Dictionary对象中存储它的FID。
我们用一个专用的过程来初始化上述数据。虽然以后各个子程序都要调用它，但实际上每一个会话期间它只执行一次：
Sub InitializeFID()
If Not IsObject(Session("FIDList")) Then
Set Session("FIDList")=Server.CreateObject("Scripting.Dictionary")
Session("FID")=0
End If
End Sub
（二）生成表单的唯一标识符
下面这个函数GenerateFID()用于生成表单的唯一标志。该函数首先将FID值加1，然后返回它：
Function GenerateFID()
InitializeFID
Session("FID") = Session("FID") + 1
GenerateFID = Session("FID")
End Function
（三）登记已提交表单
当表单成功地提交时，在Dictionary对象中登记它的唯一标识：
Sub RegisterFID()
Dim strFID
InitializeFID
strFID = Request("FID")
Session("FIDlist").Add strFID, now()
End Sub
（四）检查表单是否重复提交
在正式处理用户提交的表单之前，应该在Dictionary对象中检查它的FID是否已经登记。下面的CheckFID()函数用来完成这个工作，如已经登记，它返回FALSE，否则返回TRUE:
Function CheckFID()
Dim strFID
InitializeFID
strFID = Request("FID")
CheckFID = not Session("FIDlist").Exists(strFID)
End Function
二、如何使用
有两个地方要用到上述函数，即表单生成时与结果处理时。假设上述四个子程序已经放入包含文件Forms.inc中，下面的代码根据FID值来决定生成表单还是处理表单结果，它所描述的处理过程适合于大多数ASP应用：
<!--#include file="forms.inc"-->
<HTML>
<HEAD>
<TITLE>表单提交测试</TITLE>
</HEAD
<BODY>
<%
If Request("FID") = "" Then
GenerateForm
Else
ProcessForm
End If
%>
</BODY>
</HTML>
GenerateForm负责生成表单，表单中应该含有一个隐藏的FID，如：
<%
Sub GenerateForm()
%>
<form action="<%=Request.ServerVariables("PATH_INFO")%>" method=GET>
<input type=hidden name=FID value="<%=GenerateFID()%>">
<input type=text name="param1" value="">
<input type=submit value="OK">
</form>
<%
End Sub
%>
ProcessForm负责处理通过表单提交的内容，但在处理之前应该先调用CheckFID()检查当前表单是否已经提交，代码类如：
<%
Sub ProcessForm()
If CheckFID() Then
Response.Write "你输入的内容是" & Request.QueryString("param1")
RegisterFID
Else
Response.Write "此表单只能提交一次!"
End If
End Sub
%>
三、限制与改进措施
上面我们介绍了在当前会话期间限制同一表单被多次提交的一种方法。在实际应用中可能需要从多方面加以改进，例如：
⑴ 在登记表单ID之前检查用户输入数据的合法性，使得数据不合法时用户可以按“后退”按钮返回，在修正后再次提交同一表单。
⑵ 这种对表单提交的限制最多只能在当前会话期间有效。如果要求这种限制能够跨越多个会话，那么就要用到Cookeis或数据库来保存相关数据了。
⑶ 这种方法是不安全的。它仅用于防范误操作，不能防止熟练用户有意地多次提交同一表单。
评论 (0) All
