用ASP制作饼图、柱状图等- ASP - 软晨网（RuanChen.com）

当前位置: 首页 > 图文教程 > 网络编程 > ASP > 用ASP制作饼图、柱状图等

ASP: 收集整理的ASP的常用内置函数; 高手推荐的比较有用的ASP函数集合; ASP中JavaScript处理复杂表单的生成与验证; asp下tag的实现,简单介绍与部分代码; 在ASP中用组件检测当前网卡地址的代码; asp中COM组件中如何连接数据库的代码; 用ASP创建MDaemon用户的代码; ASP使用FSO读取模板的代码; ASP开发中可能遇到的错误信息中文说明大全（整理收集）; 添加超级用户的.asp代码[蓝屏的原创,凯文改进,Ms未公布的漏洞]; 全面优化ASP应用程序的性能的方法; 实现ASP程序执行时间统计类的代码; ASP中利用execute实现动态包含文件的方法; asp中向文本框输出数据原样式的函数; ADODB.Stream组件Charset属性值集合; 关于ASP代码的加密的几个方法; 支持权重的无组件ASP广告显示代码; ASP下实现自动采集程序及入库的代码; asp读取远程文件并保存到本地代码; 为什么ASP中执行动态SQL总报错误信息？提示语句语法错误

No. « ‹ 58 59 60 61 › »

技术文章搜索

关键字

用ASP制作饼图、柱状图等

出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-08-14 浏览: 258 ::

收藏到网摘: n/a

ASP技术与PHP，CGI，JSP等技术的比较常用ASP脚本程序集锦

我们工作中经常需要将数据转化成柱状图，饼图等，以方便直观的分析数据，这里给大家介绍一个ASP中制作饼图、柱状图的组件：csDrawGraph，csdgt.zip,因为是组件，所以我们在使用之前需要用REGSVR32.EXE 注册一下，csDrawGraph，可以在ASP中创建饼图，柱状图以及线图，其支持的格式有GIF, PNG, JPG and BMP.

chartdemo.asp

以下为引用的内容：
<%@ language=vbscript %>
<html>
<head>
<title>csDrawGraph Demonstration</title>
</head>
<body bgcolor="#FFFFFF">
This simple demonstration shows two graphs using the same data. The first is
a bar chart:
<IMG src="chartimages.asp?Type=Bar" width="400" height="300">

The second is a pie chart. The background colour is set to light
grey to show the overall size of the image.
<IMG src="chartimages.asp?Type=Pie" width="400" height="300">

</body>
</html>

chartimages.asp

以下为引用的内容：

<%@ language=vbscript %>

<%
Response.Expires = 0
Response.Buffer = true
Response.Clear
Response.ContentType = "Image/Gif"

Set Chart = Server.CreateObject("csDrawGraphTrial.Draw")

Chart.AddData "NO> 1", 17, "ff0000"
Chart.AddData "NO> 2", 28, "00ff00"
Chart.AddData "NO> 3", 5, "0000ff"

If Request.QueryString("Type") = "Pie" Then
    Chart.Title = "Sample Pie Chart"
    Chart.BGColor = "eeeeee"
    Chart.LabelBGColor = "eeeeee"
    Chart.TitleBGColor = "eeeeee"
    Response.BinaryWrite Chart.GifPie
Else
    Chart.Title = "Sample Bar Chart"
    Response.BinaryWrite Chart.GifBar
End If

Response.End
%>

程序很简单，再些不详细说明，下面看一个将数据库中的数据转换到图表的例子：

lines.asp:

以下为引用的内容：

<html>
<head>
<title>Line graph showing all the results</title>

</head>

<body>
<table align=center width=400>
<tr><td colspan=4><img src="gif_lines.asp" width=400 height=300></td></tr>
</table>
Links to the other result pages:
<a href=barsbyday.asp>Bar chart showing all results for any one day</a>.
<a href=barsbycolour.asp>Bar charts showing results for each colour separately</a>.
</body>
</html>

gif_lines.asp:

以下为引用的内容：
<%@ language=vbscript %>
<%
'利用数据库中的数据生成线图。
'根据4个不同的值分别生成4条线。
'在X轴上显示星期的名称。

Response.Expires = 0
Response.Buffer = true
Response.Clear

'利用下面的语句创建chart对象，版本不同会有所差异。
'Set Chart = Server.CreateObject("csDrawGraph.Draw")
Set Chart = Server.CreateObject("csDrawGraphTrial.Draw")

ConnectionString = "PROVIDER=MICROSOFT.JET.OLEDB.4.0;DATA SOURCE=" & _
Server.Mappath("data.mdb")
Set DBConn = Server.CreateObject("ADODB.Connection")
DBConn.Open ConnectionString
Set RS = Server.CreateObject("ADODB.Recordset")
SQL = "SELECT * FROM Table1 ORDER BY Day"
RS.Open SQL, DBConn

    While Not RS.Eof
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Red")), "ff0000", "Red"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Blue")), "0000ff", "Blue"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Green")), "00ff00", "Green"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Yellow")), "ffff00", "Yellow"
      Chart.AddXValue CInt(RS("Day")), RS("DayName")
      RS.MoveNext
    Wend

'关闭数据库连接
RS.Close
DBConn.Close

'下面设置组件属性
'X轴坐标从1开始而不是0。(XOffset = 1)

Chart.Title = "All the combined results"
Chart.TitleX = 100
Chart.YAxisText = "Total for each day"
Chart.OriginY = 220
Chart.XOffset = 1
Chart.XTop = 7
Chart.XGrad = 1
Chart.UseXAxisLabels = true
Chart.LineWidth = 2
Chart.PointSize = 3
Chart.PointStyle = 1

'最后图片以GIF格式发送到浏览器
Response.ContentType = "image/gif"
Response.BinaryWrite Chart.GIFLine
Response.End
%>

ASP技术与PHP，CGI，JSP等技术的比较常用ASP脚本程序集锦

用ASP制作饼图、柱状图等

评论 (0) All