当前位置: 首页 > 图文教程 > 网络编程 > ASP > 用ASP制作饼图、柱状图等

ASP
分享一段代码show.asp?id=26变成show/?26的形式
SQL存储过程初探
asp下载防盗链代码
解决ASP（图像）上传漏洞的方法
获取远程flash并保存到本地
多域名一网站时如果返回最原来的域名
一些值得一看的代码asp
[原创]完美解决ASP 不能更新。数据库或对象为只读。
5天学会asp
超精华的asp代码大全
用xmlhttp编写web采集程序
非常不错的flash采集程序测试通过
淘特ASP木马扫描器的代码
ASP编程入门进阶（一）：安装配置服务器
ASP编程入门进阶（二）：认识表单
6行代码实现无组件上传（author:stimson）
ASP编程入门进阶（七）：内置对象Server
有关Server.Mappath详细接触
利用SA FileUp组件进行多文件上传
个性验证码的制作方法

No. « 102 103 104 105 »

技术文章搜索

关键字

用ASP制作饼图、柱状图等

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-08-14   浏览: 227 ::
收藏到网摘: n/a

我们工作中经常需要将数据转化成柱状图，饼图等，以方便直观的分析数据， 这里给大家介绍一个ASP中制作饼图、柱状图的组件：csDrawGraph，csdgt.zip,因为是组件，所以我们在使用之前需要用REGSVR32.EXE 注册一下，csDrawGraph，可以在ASP中创建饼图，柱状图以及线图，其支持的格式有GIF, PNG, JPG and BMP.

chartdemo.asp

以下为引用的内容：
<%@ language=vbscript %>
<html>
<head>
<title>csDrawGraph Demonstration</title>
</head>
<body bgcolor="#FFFFFF">
<P>This simple demonstration shows two graphs using the same data. The first is
  a bar chart:</P>
<P align="center"><IMG src="chartimages.asp?Type=Bar" width="400" height="300">
</P>
<P align="left">The second is a pie chart. The background colour is set to light
  grey to show the overall size of the image.</P>
<P align="center"><IMG src="chartimages.asp?Type=Pie" width="400" height="300">
</P>
</body>
</html>

chartimages.asp

以下为引用的内容：

<%@ language=vbscript %>

<%
  Response.Expires = 0
  Response.Buffer = true
  Response.Clear 
  Response.ContentType = "Image/Gif"

  Set Chart = Server.CreateObject("csDrawGraphTrial.Draw")


  Chart.AddData "NO> 1", 17, "ff0000"
  Chart.AddData "NO> 2", 28, "00ff00"
  Chart.AddData "NO> 3", 5, "0000ff"

  If Request.QueryString("Type") = "Pie" Then
    Chart.Title = "Sample Pie Chart"
    Chart.BGColor = "eeeeee"
    Chart.LabelBGColor = "eeeeee"
    Chart.TitleBGColor = "eeeeee"
    Response.BinaryWrite Chart.GifPie
  Else
    Chart.Title = "Sample Bar Chart"
    Response.BinaryWrite Chart.GifBar
  End If

  Response.End
%>

程序很简单，再些不详细说明，下面看一个将数据库中的数据转换到图表的例子：

lines.asp:

以下为引用的内容：

<html>
<head>
<title>Line graph showing all the results</title>

</head>

<body>
<table align=center width=400>
  <tr><td colspan=4><img src="gif_lines.asp"  width=400 height=300></td></tr>
</table>
<p>Links to the other result pages:</p>
<p><a href=barsbyday.asp>Bar chart showing all results for any one day</a>.</p>
<p><a href=barsbycolour.asp>Bar charts showing results for each colour separately</a>.</p>
</body>
</html>


gif_lines.asp:

以下为引用的内容：
<%@ language=vbscript %>
<%
  '利用数据库中的数据生成线图。
  '根据4个不同的值分别生成4条线。
  '在X轴上显示星期的名称。

  Response.Expires = 0
  Response.Buffer = true
  Response.Clear

  '利用下面的语句创建chart对象，版本不同会有所差异。
  'Set Chart = Server.CreateObject("csDrawGraph.Draw")
  Set Chart = Server.CreateObject("csDrawGraphTrial.Draw")

  ConnectionString = "PROVIDER=MICROSOFT.JET.OLEDB.4.0;DATA SOURCE=" & _
    Server.Mappath("data.mdb")
  Set DBConn = Server.CreateObject("ADODB.Connection")
  DBConn.Open ConnectionString
  Set RS = Server.CreateObject("ADODB.Recordset")
  SQL = "SELECT * FROM Table1 ORDER BY Day"
  RS.Open SQL, DBConn

    While Not RS.Eof
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Red")), "ff0000", "Red"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Blue")), "0000ff", "Blue"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Green")), "00ff00", "Green"
      Chart.AddPoint CInt(RS("Day")), CInt(RS("Yellow")), "ffff00", "Yellow"
      Chart.AddXValue CInt(RS("Day")), RS("DayName")
      RS.MoveNext
    Wend

  '关闭数据库连接
  RS.Close
  DBConn.Close

  '下面设置组件属性
  'X轴坐标从1开始而不是0。(XOffset = 1)

  Chart.Title = "All the combined results"
  Chart.TitleX = 100
  Chart.YAxisText = "Total for each day"
  Chart.OriginY = 220
  Chart.XOffset = 1
  Chart.XTop = 7
  Chart.XGrad = 1
  Chart.UseXAxisLabels = true
  Chart.LineWidth = 2
  Chart.PointSize = 3
  Chart.PointStyle = 1

  '最后图片以GIF格式发送到浏览器
  Response.ContentType = "image/gif"
  Response.BinaryWrite Chart.GIFLine
  Response.End
%>