巧用SQL-DMO创建备份及校验的ASP应用- ASP

当前位置: 首页 > 图文教程 > 网络编程 > ASP > 巧用SQL-DMO创建备份及校验的ASP应用

ASP: ASP中实现限制IP的函数详解; Asp下实现限制IP访问的程序代码; asp下DateDiff 函数参数说明; Highlight patterns within strings; Insert Date and Time into Access; asp下调试程序的debug类; RESPONSE.WRITE和<%=%的区别; 用asp实现网页邮箱访问的方法; 编写一个含二级目录的源码(Asp+JavaScript); asp下删除Access数词库中的空记录的sql语句; asp下制做行背景颜色交替变换的表格; asp下将数据库中的信息存储至XML文件中; asp下如何在Access数据库中立即得到所插入记录的自动编号？; asp下如何在ADO服务器端利用好缓存技术？; asp调用Word打印的代码; 巧用FileSystem组件实现WEB应用中的本地特定打印的方法; 用javascript解决外部数据抓取中的乱码问题; Asp中随机产生用户密码的代码; 反SPAM新思路—换Z-BLOG的验证码！; 在Z-BLOG可用的新版ASP的GIF验证码[V70404]

No. « ‹ 59 60 61 62 › »

技术文章搜索

关键字

巧用SQL-DMO创建备份及校验的ASP应用

出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-08-14 浏览: 230 ::

收藏到网摘: n/a

使用ASP建设私人的搜索引擎技巧：用GetString来提高ASP的速度

概述

SQL分布式管理对象(SQL Distributed Management objects, SQL-DMO)为开发者提供了使用程序和脚本语言执行普通任务的方法，从而扩展了SQL Server功能。本文谈论如何巧妙的利用SQL-DMO创建数据库备份和校验的ASP应用。

前提

你需要有SQL Server数据库备份的相关知识。另外还要在global.asa文件中加入SQL-DMO库的引用。以下是SQL Server 2000的引用：

本文示例代码适用于SQL 7.0, MSDE, 和 SQL Server 2000。

喜与忧

使用SQL-DMO对象让人且喜且忧。它提供了非常丰富的功能，以至于不知该如何使用。本文只讨论示例涉及的对象属性和方法。你可以在SQL Server在线教学上找到许多相关信息。

SQLDMO.SQLServer

用于连接SQL Server数据库：

以下为引用的内容：
<%
Dim srv
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
%>

这里通过代入用户名和口令来连接SQL Server数据库。如果要使用NT的身份认证，就将它的LoginSecure属性设为真(TRUE)，忽略代入的用户名和口令，而使用NT的注册信息。

SQLDMO.Database

列出服务器中的数据库。在本文示例中，对列出的数据库进行备份。下面的代码将服务器中的数据库列于下拉菜单：

以下为引用的内容：
<%
Dim srv
Dim objDB
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
Set objDB = Server.CreateObject("SQLDMO.Database")
%>
<SELECT name="fdatabase">

<%
For Each objDB In srv.Databases
If objDB.SystemObject = False Then
%>
<OPTION><%=objDB.Name%></OPTION>
<%
End If
Next
%>
</SELECT>

SQLDMO.BackupDevice

列出服务器上安装的备份装置。我建议使用备份装置来备份数据库。因为这样可以使用SQL-DMO的校验功能来校验备份情况。下面的代码列出服务器上的备份装置：

以下为引用的内容：
<%
Dim srv
Dim objDevice
Set srv = Server.CreateObject("SQLDMO.SQLServer")
srv.LoginTimeout = 15
srv.Connect "servername", "username", "password"
Set objDevice = Server.CreateObject("SQLDMO.BackupDevice")

For Each objDevice In srv.BackupDevices
Response.Write objDevice.Name + "<BR>"
Next
%>

SQLDMO.Backup

这就是我们要用到的备份核心对象。它有许多属性，让我们作到与企业版SQL管理器一样水平的备份。先讨论一下本文示例用到的属性。

BackupSetName - 备份文件名。

Database - 要备份的数据库。

Action - 全部或增量备份。还有其他选项，不过示例中只用到这二个。

BackupSetDescription - 备份说明。

Files - 文件备份选项。标明备份文件的路径和名字，如：C:\pubs.bak。使用文件备份时，下面的备份装置名要设置为空。

Devices - 服务器上的备份装置。如果使用备份装置，上面的文件备份选项要设置为空。

TruncateLog - 备份日志选项。其选项有：

NoLog - 不备份交易日志。

NoTruncate - 备份交易日志。日志里提供时间标记。

Truncate - 备份交易日志，但不保留交易纪录。

Initialize - 如设置为真(True)，该备份装置将取代其他备份媒介而成为首选。

以下是示例中的backup.asp文件：

以下为引用的内容：
<%@ Language=VBScript %>
<HTML>
<BODY>


<%
Dim objBackup
'创建备份对象
set objBackup      = Server.CreateObject("SQLDMO.Backup")
'设置属性
objBackup.BackupSetName = Request("fname")
objBackup.Database       = Request("fdatabase")
objBackup.Action         = Request("fAction")
objBackup.BackupSetDescription = Request("fdescription")
objBackup.Files        = Request("fbackupfile")
objBackup.Devices      = Request("fdevice")
objBackup.TruncateLog = Request("flog")
objBackup.Initialize   = Request("finit")
'备份数据库
objBackup.SQLBackup srv
'断开与服务器的连接
srv.disconnect
'释放
set srv = nothing
set objBackup = Nothing
%>
<P>
The backup was started, use the <A HREF="devices.asp">verify</A>
option to see if it completed successfully.
<A HREF="default.asp">Click here</A> to return.
</P>
</BODY>
</HTML>

备份校验

如果用VB或C++编程，可以用事件触发来校验备份过程，但在ASP中不行。我们用SQLDMO.BackupDevice对象的ReadBackupHeader方法来确认备份是否成功。

下面是verify.asp文件代码，它列出备份装置名字并提供最近备份的有关信息。

以下为引用的内容：
<%@ Language=VBScript %>
<HTML>
<BODY>


<P>
<%
Dim objDevice
Dim objResults
Dim iCount
Dim xCount
'创建备份装置对象
Set objDevice = Server.CreateObject("SQLDMO.BackupDevice")
    '循环直到找到匹配的装置
    For Each objDevice In srv.BackupDevices
      If objDevice.Name = Request("fname") Then
        '找到匹配装置，开始读取结果
        Set objResults = objDevice.ReadBackupHeader
        For iCount = 1 To objResults.Rows
          For xCount = 1 To objResults.Columns%>
           <B><%=objResults.ColumnName(xcount)%></B>:
           <%=objResults.GetColumnString(icount,xcount)%><br>
          <%Next %>
          <HR>
        <%Next %>
     <%End If%>
   <%Next%>
<%
srv.Disconnect
set srv = nothing
set objDevice = nothing
set objResults = nothing
%>
</BODY>
</HTML>

ReadBackupHeader方法返回QueryResults对象。用其Rows属性可以得到备份的纪录数。然后对每行纪录作列信息搜索。

其他功能

SQL-DMO还提供远程备份和恢复功能。本文没有涉及数据库恢复，但SQL-DMO有很强的恢复功能。

使用ASP建设私人的搜索引擎技巧：用GetString来提高ASP的速度

巧用SQL-DMO创建备份及校验的ASP应用

评论 (0) All