ASP实例：利用缓存提高数据显示效率- ASP

当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP实例：利用缓存提高数据显示效率

ASP: BytesToBstr获取的源码转换为中文的代码; PostHttpPage用asp是实现模拟登录效果的代码; asp下实现UrlEncoding转换编码的代码; GetBody asp实现截取字符串的代码; asp之GetArray提取链接地址，以$Array$分隔的代码; DefiniteUrl asp将相对地址转换为绝对地址的代码; ReplaceSaveRemoteFile 替换、保存远程图片的代码; ReSaveRemoteFile函数之asp实现查找文件保存替换的代码; FormatRemoteUrl函数之asp实现格式化成当前网站完整的URL-将相对地址转换为绝对地址的代码; ReplaceTrim 函数之asp实现过滤掉字符中所有的tab和回车和换行的代码; CheckFile函数之asp实现检查某一文件是否存在的代码; SaveRemoteFile函数之asp实现保存远程的文件到本地的代码; FpHtmlEnCode 函数之标题过滤特殊符号的代码; GetPaing 函数之asp采集函数中用到的获取分页的代码; ScriptHtml 函数之过滤html标记的asp代码; asp实现检查目录是否存在与建立目录的函数; ShowPage 显示“上一页下一页”等信息的封装代码; JoinChar 向地址中加入 ? 或 & 用于实现传参; CreateKeyWord asp实现的由给定的字符串生成关键字的代码; Server.Execute方法执行指定的ASP程序

No. « ‹ 66 67 68 69 › »

技术文章搜索

关键字

ASP实例：利用缓存提高数据显示效率

出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-08-14 浏览: 250 ::

收藏到网摘: n/a

ASP技巧实例：ASP实现最简洁的多重查询的解决方案 ASP实例代码：搞个长文章分页代码

实例演示：先建立一个简单的数据库，写个function读取一下，写入一个dim变量temp中：

ASP代码

以下为引用的内容：
<%
Function DisplayRecords()
    Dim sql, conn, rs
    sql = "SELECT id, [szd_f], [szd_t] FROM admin"
    Set conn = Server.CreateObject("ADODB.Connection")
    conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ="&Server.MapPath("db.mdb")
    Set rs = Server.CreateObject("ADODB.Recordset")
    rs.Open sql, conn, 1, 3
    If Not rs.EOF Then
      Dim temp
      temp = "<table width=""90%"" align=""center"""
      temp = temp & " border=""1"" bordercolor=""silver"""
      temp = temp & " cellspacing=""2"" cellpadding=""0"">"
      temp = temp & "<tr bgcolor=""#CCDDEE""><td width=""5%"""
      temp = temp & ">ID</td><td>操作</td>"
      temp = temp & "<td>数值</td></tr>"
    While Not rs.EOF
      temp = temp & "<tr><td bgcolor=""#CCDDEE"">"
      temp = temp & rs("ID") & "</td><td>" & rs("szd_f")
      temp = temp & "</td><td>" & rs("szd_t")
      temp = temp & "</td></tr>"
      rs.MoveNext
    Wend
      temp = temp & "</table>"
      DisplayRecords = temp
    Else
      DisplayRecords = "Data Not Available."
    End If
    rs.Close
    conn.Close
    Set rs = Nothing
    Set conn = Nothing
End Function
'写入缓存
Function DisplayCachedRecords(Secs)
    Dim retVal, datVal, temp1
        retVal = Application("cache_demo")
        datVal = Application("cache_demo_date")
        If datVal = "" Then
            datVal = DateAdd("s",Secs,Now)
        End If
        temp1 = DateDiff("s", Now, datVal)
    If temp1 > 0 And retVal <> "" Then
        DisplayCachedRecords = retVal
        ' Debugging Code :
        Response.Write "<b><font color=""green"">利用缓存读取数据"
        Response.Write " ... (" & temp1 & " 秒剩余)</font></b>"
        Response.Write "<br><br>"
    Else
        Dim temp2
        ' Change DisplayRecords() to the function whose
        ' value you want to cache
        temp2 = DisplayRecords()
        Application.Lock
            Application("cache_demo") = temp2
            Application("cache_demo_date") = DateAdd("s",Secs,Now)
        Application.UnLock
        DisplayCachedRecords = temp2
        ' Debugging Code :
        Response.Write "<b><font color=""red"">刷新缓存显示 ..."
        Response.Write "</font></b><br><br>"
    End If
End Function
%>

<html>
<head>
    <title>利用缓存从数据库---读取数据</title>
    <style>
    body, p, td { font-family:Sans-Serif; font-size:8pt; }
    td { padding-left: 5; }
    </style>
</head>
<body>
<%
    Dim t1, t2
        t1 = Timer
    Response.Write DisplayCachedRecords(20)
        t2 = Timer
%>
<p align="center">
停留时间: <%= Left((CDbl((t2 - t1) * 1000.0)), 5) %> ms
</p>
</body>
</html>

ASP技巧实例：ASP实现最简洁的多重查询的解决方案 ASP实例代码：搞个长文章分页代码

ASP实例：利用缓存提高数据显示效率

评论 (0) All