当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP实例：利用缓存提高数据显示效率

ASP
ASP实现表单中容量大的数据的提交方法
强烈推荐ASP初学者观看：常用ASP技术
认真学习ASP内置对象Session的应用
asp函数转换xml中的实体字符[转义符]
ASP防止重复多次提交表单的方法
ASP处理XSLT转换XML的实现
ASP中将Excel数据导入到Access
[推荐]ASP 编程中 20 个非常有用的例子
[推荐]每个ASP程序员必备的知识
[推荐]ASP初学者常犯的几个错误
解决杀毒软件误删asp文件的方法
用VB编写ActiveX DLL实现ASP编程
asp.net结合js的网页打印程序
ASP网站远程客户实现EXCEL打印功能
ASP程序中使用断开的数据记录集
利用ASP发送和接收XML数据的处理方法
20种看ASP程序源码的方法及工具
ASP技巧：禁用FileSystemObject组件
在ASP中使用SQL语句:开始执行
ASP编写计数器的优化方法

No. « 20 21 22 23 »

技术文章搜索

关键字

ASP实例：利用缓存提高数据显示效率

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-08-14   浏览: 83 ::
收藏到网摘: n/a

实例演示：先建立一个简单的数据库，写个function读取一下，写入一个dim变量temp中：

ASP代码

以下为引用的内容：
<%       
Function DisplayRecords()       
    Dim sql, conn, rs       
    sql = "SELECT id, [szd_f], [szd_t] FROM admin"      
    Set conn = Server.CreateObject("ADODB.Connection")       
    conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ="&Server.MapPath("db.mdb")       
    Set rs = Server.CreateObject("ADODB.Recordset")       
    rs.Open sql, conn, 1, 3
    If Not rs.EOF Then      
      Dim temp       
      temp = "<table width=""90%"" align=""center"""      
      temp = temp & " border=""1""  bordercolor=""silver"""      
      temp = temp & " cellspacing=""2"" cellpadding=""0"">"      
      temp = temp & "<tr bgcolor=""#CCDDEE""><td width=""5%"""      
      temp = temp & ">ID</td><td>操作</td>"
      temp = temp & "<td>数值</td></tr>"
    While Not rs.EOF       
      temp = temp & "<tr><td bgcolor=""#CCDDEE"">"      
      temp = temp & rs("ID") & "</td><td>" & rs("szd_f")       
      temp = temp & "</td><td>" & rs("szd_t")       
      temp = temp & "</td></tr>"      
      rs.MoveNext       
    Wend
      temp = temp & "</table>"
      DisplayRecords = temp       
    Else      
      DisplayRecords = "Data Not Available."      
    End If
    rs.Close       
    conn.Close       
    Set rs = Nothing      
    Set conn = Nothing      
End Function
'写入缓存       
Function DisplayCachedRecords(Secs)       
    Dim retVal, datVal, temp1       
        retVal = Application("cache_demo")       
        datVal = Application("cache_demo_date")
        If datVal = "" Then      
            datVal = DateAdd("s",Secs,Now)       
        End If
        temp1 = DateDiff("s", Now, datVal)      
    If temp1 > 0 And retVal <> "" Then      
        DisplayCachedRecords = retVal
        ' Debugging Code :       
        Response.Write "<b><font color=""green"">利用缓存读取数据"      
        Response.Write " ... (" & temp1 & " 秒剩余)</font></b>"      
        Response.Write "<br><br>"      
    Else
        Dim temp2       
        ' Change DisplayRecords() to the function whose        
        ' value you want to cache       
        temp2 = DisplayRecords()
        Application.Lock       
            Application("cache_demo") = temp2       
            Application("cache_demo_date") = DateAdd("s",Secs,Now)       
        Application.UnLock
        DisplayCachedRecords = temp2
        ' Debugging Code :       
        Response.Write "<b><font color=""red"">刷新缓存显示 ..."      
        Response.Write "</font></b><br><br>"
    End If      
End Function      
%>       
<!--       
Response.Write DisplayRecords()       
-->
<html>       
<head>       
    <title>利用缓存从数据库---读取数据</title>       
    <style>       
    body, p, td { font-family:Sans-Serif; font-size:8pt; }       
    td { padding-left: 5; }       
    </style>       
</head>       
<body>       
<%       
    Dim t1, t2       
        t1 = Timer       
    Response.Write DisplayCachedRecords(20)       
        t2 = Timer       
%>
<p align="center">       
停留时间: <%= Left((CDbl((t2 - t1) * 1000.0)), 5) %> ms       
</p>
</body>       
</html>