当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP实例：利用缓存提高数据显示效率

ASP
通过ASP与ACCESS数据库建立连接（附源码）(1)
通过ASP与ACCESS数据库建立连接（附源码）(2)
通过ASP与ACCESS数据库建立连接（附源码）(3)
关于页面局部刷新例程
仿照CHINAASP论坛中TOP10写的部分显示代码
用ASP做一个记事本编缉器（附源码）
让您的主页支持各种浏览设备（ASP+篇)(下）
用ASP开发一个在线考试程序（五）
用ASP开发一个在线考试程序（六）
用ASP开发一个在线考试程序（七）
用ASP开发一个在线考试程序（八）
用ASP开发一个在线考试程序（九）
用SQL Server为Web浏览器提供图像1
用SQL Server为Web浏览器提供图像2
用SQL Server为Web浏览器提供图像3(end)
制作一个个人搜索引擎（源码）
制作一个简单的服务器端控制
用Access制作一个功能完善的论坛（源程序）
广告播放和跟踪系统的制作
动态广告管理程序制作例子

No. « 212 213 214 215 »

技术文章搜索

关键字

ASP实例：利用缓存提高数据显示效率

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-08-14   浏览: 56 ::
收藏到网摘: n/a

实例演示：先建立一个简单的数据库，写个function读取一下，写入一个dim变量temp中：

ASP代码

以下为引用的内容：
<%       
Function DisplayRecords()       
    Dim sql, conn, rs       
    sql = "SELECT id, [szd_f], [szd_t] FROM admin"      
    Set conn = Server.CreateObject("ADODB.Connection")       
    conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ="&Server.MapPath("db.mdb")       
    Set rs = Server.CreateObject("ADODB.Recordset")       
    rs.Open sql, conn, 1, 3
    If Not rs.EOF Then      
      Dim temp       
      temp = "<table width=""90%"" align=""center"""      
      temp = temp & " border=""1""  bordercolor=""silver"""      
      temp = temp & " cellspacing=""2"" cellpadding=""0"">"      
      temp = temp & "<tr bgcolor=""#CCDDEE""><td width=""5%"""      
      temp = temp & ">ID</td><td>操作</td>"
      temp = temp & "<td>数值</td></tr>"
    While Not rs.EOF       
      temp = temp & "<tr><td bgcolor=""#CCDDEE"">"      
      temp = temp & rs("ID") & "</td><td>" & rs("szd_f")       
      temp = temp & "</td><td>" & rs("szd_t")       
      temp = temp & "</td></tr>"      
      rs.MoveNext       
    Wend
      temp = temp & "</table>"
      DisplayRecords = temp       
    Else      
      DisplayRecords = "Data Not Available."      
    End If
    rs.Close       
    conn.Close       
    Set rs = Nothing      
    Set conn = Nothing      
End Function
'写入缓存       
Function DisplayCachedRecords(Secs)       
    Dim retVal, datVal, temp1       
        retVal = Application("cache_demo")       
        datVal = Application("cache_demo_date")
        If datVal = "" Then      
            datVal = DateAdd("s",Secs,Now)       
        End If
        temp1 = DateDiff("s", Now, datVal)      
    If temp1 > 0 And retVal <> "" Then      
        DisplayCachedRecords = retVal
        ' Debugging Code :       
        Response.Write "<b><font color=""green"">利用缓存读取数据"      
        Response.Write " ... (" & temp1 & " 秒剩余)</font></b>"      
        Response.Write "<br><br>"      
    Else
        Dim temp2       
        ' Change DisplayRecords() to the function whose        
        ' value you want to cache       
        temp2 = DisplayRecords()
        Application.Lock       
            Application("cache_demo") = temp2       
            Application("cache_demo_date") = DateAdd("s",Secs,Now)       
        Application.UnLock
        DisplayCachedRecords = temp2
        ' Debugging Code :       
        Response.Write "<b><font color=""red"">刷新缓存显示 ..."      
        Response.Write "</font></b><br><br>"
    End If      
End Function      
%>       
<!--       
Response.Write DisplayRecords()       
-->
<html>       
<head>       
    <title>利用缓存从数据库---读取数据</title>       
    <style>       
    body, p, td { font-family:Sans-Serif; font-size:8pt; }       
    td { padding-left: 5; }       
    </style>       
</head>       
<body>       
<%       
    Dim t1, t2       
        t1 = Timer       
    Response.Write DisplayCachedRecords(20)       
        t2 = Timer       
%>
<p align="center">       
停留时间: <%= Left((CDbl((t2 - t1) * 1000.0)), 5) %> ms       
</p>
</body>       
</html>