ASP实例：利用缓存提高数据显示效率- ASP

当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP实例：利用缓存提高数据显示效率

ASP: 用asp执行DTC; 利用ADODB.Stream使用浏览器下载服务器文件; 应用数据库的唯一性约束并在asp中捕捉数据库的错误; 用ASP编程控制在IIS建立Web站点; asp实现k线图(在线); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(7); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(6); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(5); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(4); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(3); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(2); 在ASP中用EasyMailObject组件处理Exchange邮件源代码(1); 用文本+ASP打造新闻发布系统。几点补充; 用文本+ASP打造新闻发布系统(五)新闻修改; 用文本+ASP打造新闻发布系统(四)新闻删除; 用文本+ASP打造新闻发布系统(三)新闻列表显示; 用文本+ASP打造新闻发布系统(二)新闻添加; ASP作的剪包锤游戏; ASP注册表项目修改; 构建稳定的服务器端组件的七个步骤

No. « ‹ 111 112 113 114 › »

技术文章搜索

关键字

ASP实例：利用缓存提高数据显示效率

出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-08-14 浏览: 186 ::

收藏到网摘: n/a

ASP技巧实例：ASP实现最简洁的多重查询的解决方案 ASP实例代码：搞个长文章分页代码

实例演示：先建立一个简单的数据库，写个function读取一下，写入一个dim变量temp中：

ASP代码

以下为引用的内容：
<%
Function DisplayRecords()
    Dim sql, conn, rs
    sql = "SELECT id, [szd_f], [szd_t] FROM admin"
    Set conn = Server.CreateObject("ADODB.Connection")
    conn.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ="&Server.MapPath("db.mdb")
    Set rs = Server.CreateObject("ADODB.Recordset")
    rs.Open sql, conn, 1, 3
    If Not rs.EOF Then
      Dim temp
      temp = "<table width=""90%"" align=""center"""
      temp = temp & " border=""1"" bordercolor=""silver"""
      temp = temp & " cellspacing=""2"" cellpadding=""0"">"
      temp = temp & "<tr bgcolor=""#CCDDEE""><td width=""5%"""
      temp = temp & ">ID</td><td>操作</td>"
      temp = temp & "<td>数值</td></tr>"
    While Not rs.EOF
      temp = temp & "<tr><td bgcolor=""#CCDDEE"">"
      temp = temp & rs("ID") & "</td><td>" & rs("szd_f")
      temp = temp & "</td><td>" & rs("szd_t")
      temp = temp & "</td></tr>"
      rs.MoveNext
    Wend
      temp = temp & "</table>"
      DisplayRecords = temp
    Else
      DisplayRecords = "Data Not Available."
    End If
    rs.Close
    conn.Close
    Set rs = Nothing
    Set conn = Nothing
End Function
'写入缓存
Function DisplayCachedRecords(Secs)
    Dim retVal, datVal, temp1
        retVal = Application("cache_demo")
        datVal = Application("cache_demo_date")
        If datVal = "" Then
            datVal = DateAdd("s",Secs,Now)
        End If
        temp1 = DateDiff("s", Now, datVal)
    If temp1 > 0 And retVal <> "" Then
        DisplayCachedRecords = retVal
        ' Debugging Code :
        Response.Write "<b><font color=""green"">利用缓存读取数据"
        Response.Write " ... (" & temp1 & " 秒剩余)</font></b>"
        Response.Write "<br><br>"
    Else
        Dim temp2
        ' Change DisplayRecords() to the function whose
        ' value you want to cache
        temp2 = DisplayRecords()
        Application.Lock
            Application("cache_demo") = temp2
            Application("cache_demo_date") = DateAdd("s",Secs,Now)
        Application.UnLock
        DisplayCachedRecords = temp2
        ' Debugging Code :
        Response.Write "<b><font color=""red"">刷新缓存显示 ..."
        Response.Write "</font></b><br><br>"
    End If
End Function
%>

<html>
<head>
    <title>利用缓存从数据库---读取数据</title>
    <style>
    body, p, td { font-family:Sans-Serif; font-size:8pt; }
    td { padding-left: 5; }
    </style>
</head>
<body>
<%
    Dim t1, t2
        t1 = Timer
    Response.Write DisplayCachedRecords(20)
        t2 = Timer
%>
<p align="center">
停留时间: <%= Left((CDbl((t2 - t1) * 1000.0)), 5) %> ms
</p>
</body>
</html>

ASP技巧实例：ASP实现最简洁的多重查询的解决方案 ASP实例代码：搞个长文章分页代码

ASP实例：利用缓存提高数据显示效率

评论 (0) All