当前位置: 首页 > 图文教程 > 网络编程 > ASP > ADO初学者教程：ADO 通过GetString()加速脚本

ASP
ASP连接SQL2005数据库连接代码
ASP程序与SQL存储过程结合使用详解
asp 小偷采集程序原理与常用函数方法
防盗链接ASP函数
asp将table生成excel文件(xls)
asp实现新评论自动发短信提示的代码
asp最简单的生成验证码代码
ASP 常见对象总结(熟悉一下利用以后的开发使用)
ASP UTF-8编码生成静态网页的函数
ASP+FSO生成的网页文件默认编码格式以及转换成UTF-8编码方法
asp Access数据备份,还原,压缩类代码
asp fso操作类
ASP 自动采集实现代码
asp 一些支付接口
ASP 递归调用 已知节点查找根节点的函数
用asp实现读取文件的最后一行的代码
用asp实现的获取文件夹中文件的个数的代码
ASP与Excel结合生成数据表和Chart图的代码
iis7 ASP+Access数据库连接错误
ASP 日期的加减运算实现代码

No. « 220 221 222 223 »

技术文章搜索

关键字

ASP 中的 ADO初学者教程：ADO 通过GetString()加速脚本

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-08-14   浏览: 74 ::
收藏到网摘: n/a

作者：请使用GetString()方法来加速您的ASP脚本（来代替多行的Response.Write）。

实例

使用 GetString()

如何使用GetString()在HTML表格中显示记录集中的数据。

多行Response.Write

下面的例子演示了在HTML表格中显示数据库查询的一种方法：

以下为引用的内容：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>
<table border="1" width="100%">
<%do until rs.EOF%>
   <tr>
      <td><%Response.Write(rs.fields("Companyname"))%></td>
      <td><%Response.Write(rs.fields("Contactname"))%></td>
   </tr>
<%rs.MoveNext
loop%>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

对于一个大型的查询来说，这样做会增加脚本的处理时间，这是由于服务器需要处理大量的Response.Write命令。

解决的办法是创建全部字符串，从<table>到</table>，然后将其输出 - 只使用一次Response.Write。

GetString() 方法

GetString()方法使我们有能力仅使用一次Response.Write，就可以显示所有的字符串。同时它甚至不需要do..loop代码以及条件测试来检查记录集是否处于EOF。

语法

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

如需使用来自记录集的数据创建一个HTML表格，我们仅仅需要使用以上参数中的三个（所有的参数都是可选的）：

coldel - 用作列分隔符的HTML

rowdel - 用作行分隔符的HTML

nullexpr - 当列为空时所使用的HTML

注释：The GetString()方法是ADO 2.0的特性。您可从下面的地址下载ADO 2.0：http://www.microsoft.com/data/download.htm

在下面的例子中，我们将使用GetString()方法，把记录集存为一个字符串：

以下为引用的内容：

<html>
<body>
<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"
set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
str=rs.GetString(,,"</td><td>","</td></tr><tr><td>","&nbsp;")
%>
<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>
<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

上面的变量str包含着由SELECT语句返回的所有列和行的一个字符串。在每列之间会出现</td><td>，在每行之间会出现</td></tr><tr><td>。这样，仅使用一次Response.Write，我们就得到了需要的HTML。