我们先建立一个数据表，结构如下图(LID 为左值，RID 为右值，Tree 为节点深度，Name 和 ID 就不多说了，节点的索引和名称)

我们可以使用下面的存储过程来获得一个节点和其子节点：

CREATE PROCEDURE CLSP_ZoneSelect  
(  
    @Root INT,  
    @Tree INT 
)  
AS 
    SELECT Z.ID,Z.Tree,Z.Name  
    FROM CL_ZoneData AS Z,CL_ZoneData AS P  
    WHERE   P.ID = @Root  
         AND Z.LID >= P.LID AND Z.RID <= P.RID  
            AND (@Tree = 0 OR Z.Tree <= P.Tree + @Tree)  
    ORDER BY Z.LID ASC 
GO 

我们可以用下面这个存储过程来在一个节点下插入新的子节点：

CREATE PROCEDURE CLSP_ZoneInsert  
(  
    @Root INT,  
    @Name NVARCHAR(50)  
)  
AS 
    DECLARE @RID AS INT,@NID AS INT,@Tree AS INT 
 
    SET @RID = 1  
    SET @NID = 0  
    SET @Tree = 1  
 
    IF @Root = 0  
    BEGIN 
        SELECT TOP 1 @RID = RID + 1  
        FROM CL_CateData ORDER BY RID DESC 
    END 
    ELSE 
    BEGIN 
        SELECT @RID = RID, @Tree = Tree + 1  
        FROM CL_ZoneData WHERE ID = @Root  
    END 
 
    IF @Root = 0 OR @RID > 1  
    BEGIN 
        UPDATE CL_ZoneData SET RID = RID + 2 WHERE RID >= @RID  
        UPDATE CL_ZoneData SET LID = LID + 2 WHERE LID > @RID  
 
        INSERT INTO CL_ZoneData(LID,RID,Tree,Name)  
        VALUES (@RID,@RID + 1,@Tree,@Name)  
 
        SET @NID = SCOPE_IDENTITY()  
    END 
    SELECT @NID  
GO 

删除一个节点可以用下面的存储过程：

CREATE PROCEDURE CLSP_ZoneDelete  
(  
    @ID INT 
)   
AS 
    DECLARE @LID AS INT, @RID AS INT, @WID AS INT, @DID AS INT 
    SET @DID = 0  
    SELECT @DID = ID, @LID = LID, @RID = RID, @WID = RID - LID + 1 FROM CL_ZoneData WHERE ID = @ID  
    IF @DID != 0  
    BEGIN 
        DELETE FROM CL_ZoneData WHERE LID BETWEEN @LID AND @RID  
        UPDATE CL_ZoneData SET RID = RID - @WID WHERE RID > @RID  
        UPDATE CL_ZoneData SET LID = LID - @WID WHERE LID > @RID  
    END 
    SELECT @DID  
GO  

评论 (0) All

登陆 还没注册？