当前位置: 首页 > 图文教程 > 网络编程 > ASP > 关于创建多级文件夹的ASP函数实例

ASP
asp OpenTextFile文本读取与写入实例代码
在ASP编程中nothing代表什么意思?
asp之让Session永不过期
ASP获取ACCESS数据库表名及结构的代码
推荐一篇不错的新手asp编程的基本法则
最简洁的asp多重查询的解决方案
ASP 判断是否有中文的代码
asp.net常用函数收藏
asp下几种常用排序算法
asp获取数据库中表名和字段名的代码
简单的asp采集代码教程
asp生成带有样式的word文件方法
实用301转向到另一域名相应页面的asp代码
asp伪继承初探_实例代码
asp代理采集的核心函数代码
js table排序类代码
ASP UTF-8页面乱码+GB2312转UTF-8 +生成UTF-8格式的文件(编码)
Asp生成RSS的类_给网站加上RSS
utf-8 网页不显示+utf-8网页乱码的通用解决方法
asp截取指定英汉混合字符串_支持中文

No. « 78 79 80 81 »

技术文章搜索

关键字

关于创建多级文件夹的ASP函数实例

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-09-28   浏览: 46 ::
收藏到网摘: n/a

FileSystemObject中有个方法创建文件夹的方法CreateFolder，但是这个方法只能在其上一级文件夹存在的情况下创建新的文件夹，所以我就写了一个自动创建多级文件夹的函数，在生成静态页面等方面使用非常方便。函数如下：

以下为引用的内容：
'--------------------------------
'自动创建指定的多级文件夹
'strPath为绝对路径
Function AutoCreateFolder(strPath) 'As Boolean
        On Error Resume Next
        Dim astrPath, ulngPath, i, strTmpPath
        Dim objFSO
        If InStr(strPath, "\") <=0 or InStr(strPath, ":") <= 0 Then
                AutoCreateFolder = False
                Exit Function
        End If
        Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
        If objFSO.FolderExists(strPath) Then
                AutoCreateFolder = True
                Exit Function
        End If
        astrPath = Split(strPath, "\")
        ulngPath = UBound(astrPath)
        strTmpPath = ""
        For i = 0 To ulngPath
                strTmpPath = strTmpPath & astrPath(i) & "\"
                If Not objFSO.FolderExists(strTmpPath) Then
                        '创建
                        objFSO.CreateFolder(strTmpPath)
                End If
        Next
        Set objFSO = Nothing
        If Err = 0 Then
                AutoCreateFolder = True
        Else
                AutoCreateFolder = False
        End If
End Function 

'调用方法:

以下为引用的内容：

MyPath = Server.MapPath("a/b/c")
If AutoCreateFolder(MyPath) Then
        Response.Write "创建文件夹成功"
Else
        Response.Write "创建文件夹失败"
End If