当前位置: 首页 > 图文教程 > 网络编程 > Javascript > 超强幻灯片播放脚本（VBS）

Javascript
写的htc的数据表格
幻宇的层模拟窗口效果－提供演示和下载
javascript 播放器 控制
一个无限级XML绑定跨框架菜单（For IE）
innerHTML，outerHTML,innerTEXT三者之间的区别
无间断滚动的新闻文章列表 多浏览器兼容
图片连续不间断滚动像册
关于图片验证码设计的思考
Js之软键盘实现(js源码)
js技巧收集(200多个) 超强推荐
图片自动播放也可通过按钮控制显示
照片各部分的彩色与黑白交替更换
select发展史 超强
无聊，写了个日历程序，欢迎拍砖
greybox：不开新窗口看新的网页
nicejforms：美化表单不用愁
用jquery来定位
动态调用css文件：jquery的应用
用YUI做了个标签浏览效果
JS轻松实现CSS设置,DIV+CSS常用CSS设置

No. « 201 202 203 204 »

技术文章搜索

关键字

Javascript 中的 超强幻灯片播放脚本（VBS）

出处:互联网   整理: 软晨网（RuanChen.com）   发布: 2009-08-10   浏览: 225 ::
收藏到网摘: n/a

用 VBScript 编写，没有专门的类别，只好放到 Javascript 分类了。

<HTML>
  <HEAD>
    <TITLE>夜雨休闲 - 幻灯片播放</TITLE>
    <META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=gb2312">
    <LINK HREF="Images/Style.css" REL="stylesheet">
  </HEAD>
 
<SCRIPT language="VBScript">
  
  '***************************************************
  '            模拟幻灯片播放脚本程序
  '             夜雨休闲 By 2003-11
  '***************************************************
  
  Dim FileList,FileListArr
  FileList = "001.jpg,002.jpg,003.jpg,004.jpg,005.jpg,006.jpg,007.jpg,008.jpg,009.jpg,010.jpg"
  FileListArr = Split(FileList,",")
  
  Dim CanPlay
  CanPlay = CInt(Split(Split(navigator.appVersion,";")(1)," ")(2))>5
  
  Dim FilterStr
  FilterStr = "RevealTrans(duration=2,transition=23)"
  FilterStr = FilterStr + ";BlendTrans(duration=2)"
  
  If CanPlay Then
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Pixelate(,enabled=false,duration=2,maxSquare=25)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Fade(duration=2,overlap=0)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.GradientWipe(duration=2,gradientSize=0.25,motion=forward )"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Stretch(duration=2,stretchStyle=PUSH)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Wheel(duration=2,spokes=16)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.RandomDissolve(duration=2)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Spiral(duration=2,gridSizeX=50,gridSizeY=50)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.Slide(duration=2,bands=1,slideStyle=SWAP)"
    FilterStr = FilterStr + ";progid:DXImageTransform.Microsoft.RadialWipe(duration=2,wipeStyle=CLOCK)"
  Else
    Msgbox "幻灯片播放具有多种动态图片切换效果，但此功能需要您的浏览器为IE5.5或以上版本，否则您将只能看到部分的切换效果。",64
  End If

  Dim FilterArr
  FilterArr = Split(FilterStr,";")

  Dim PlayImg_M
  PlayImg_M = 5 * 1000  '切换时间（毫秒）

  Dim I
  I = 1

  Sub ChangeImg
    Do While FileListArr(I)=""
      I = I + 1
      If I>UBound(FileListArr) Then I = 0
    Loop
    Dim J
    If I>UBound(FileListArr) Then I = 0
    Randomize
    J = Int(Rnd * (UBound(FilterArr)+1))
    Img.style.filter = FilterArr(J)
    Img.filters(0).Apply
    Img.Src = FileListArr(I)
    Img.filters(0).play
    I = I + 1
    If I>UBound(FileListArr) Then I = 0
    TempImg.Src = FileListArr(I)
    
    SetTimeout "ChangeImg",PlayImg_M
  End Sub
</SCRIPT>

<BODY BGCOLOR="#000000">
<TABLE WIDTH="100%" height="100%" BORDER="0" CELLSPACING="0" CELLPADDING="0">
  <TR ID="NoScript">
    <TD Align="Center" Style="Color:White">对不起，图片浏览功能需脚本支持，但您的浏览器已经设置了禁止脚本运行。请您在浏览器设置中调整有关安全选项。</TD>
  </TR>
  <TR Style="Display:none" ID="CanRunScript">
    <TD HEIGHT="100%" Align="Center" vAlign="Center">
      <Img ID="Img" Border="0" >
    </TD>
  </TR>
  <TR Style="Display:none">
    <TD><Img ID="TempImg" Border="0"></TD>
  </TR>
 
</TABLE>

<Script Language="VBScript">
  NoScript.Style.Display = "none"
  CanRunScript.Style.Display = ""
  Img.Src = FileListArr(0)
  SetTimeout "ChangeImg", PlayImg_M
</Script>