繁體中文当前位置: 首页 > 图文教程 > 数据库 > MSSQL > sqlserver 数据库日志备份和恢复步骤
- MSSQL
- ACCESS改为SQL需要注意哪几个地方
- 把sql数据和access数据整合成一个数据集
- SQL中Print语句的烦恼
- 关于SQL server中字段值为null的查询
- 得出SQL语句的执行时间的方法
- 如何在SqlServer与oracel中进行分页的讨论!
- 分页SQLServer存储过程
- 怎么清除sql server日志
- Sql数据库MDF数据文件数据库恢复
- SQL Server存储图像数据的策略与方法
- sql server关于函数中如何使用Getdate()
- 将使用Access的论坛迁移到SqLServer中
- ACCESS：跨数据库查询的SQL语句
- SQLSERVER扩展存储过程XP_CMDSHELL的简单应用
- 在SQL Server中快速删除重复记录
- 调整SQLServer2000运行中数据库结构
- SQL Server中查询时显示行号的方法
- 从数据库中随机抽N条记录
- 确保所有的非空（Non-NULL）值都是唯一的
- 使用视图控制用户对数据访问
MSSQL 中的 sqlserver 数据库日志备份和恢复步骤
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 240 ::
收藏到网摘: n/a
sqlserver 数据库日志备份和恢复实现步骤 --创建测试数据库
CREATE DATABASE Db
GO
--对数据库进行备份
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT
GO
--创建测试表
CREATE TABLE Db.dbo.TB_test(ID int)
--延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)
WAITFOR DELAY '00:00:01'
GO
--假设我们现在误操作删除了 Db.dbo.TB_test 这个表
DROP TABLE Db.dbo.TB_test
--保存删除表的时间
SELECT dt=GETDATE() INTO #
GO
--在删除操作后,发现不应该删除表 Db.dbo.TB_test
--下面演示了如何恢复这个误删除的表 Db.dbo.TB_test
--首先,备份事务日志(使用事务日志才能还原到指定的时间点)
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT
GO
--接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY
GO
--将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM # --获取比表被删除的时间略早的时间
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt
GO
--查询一下,看表是否恢复
SELECT * FROM Db.dbo.TB_test
/*--结果:
ID
-----------
（所影响的行数为 0 行）
--*/
--测试成功
GO
--最后删除我们做的测试环境
DROP DATABASE Db
DROP TABLE #
评论 (0) All
