繁體中文当前位置: 首页 > 图文教程 > 数据库 > MSSQL > sqlserver 数据库日志备份和恢复步骤
- MSSQL
- 用SQL语句实现替换字符串
- mssql查找备注(text,ntext)类型字段为空的方法
- MSSQL数据类型及长度限制详细说明
- SQL Server下几个危险的扩展存储过程
- 一些SQL Server存储过程参数及例子
- sql高级技巧几个有用的Sql语句
- SQL语句实现SQL Server 2000及Sql Server 2005日志收缩(批量)
- 用SQL建立索引的方法步骤
- MSsql每天自动备份数据库并每天自动清除log的脚本
- mssql无数据库日志文件恢复数据库的方法
- SQL Server常用管理命令小结
- SQL SERVER性能优化综述(很好的总结,不要错过哦)
- sqlserver 游标的简单示例
- sqlserver只有MDF文件恢复数据库的方法
- 在SQL Server启动时自动执行存储过程。
- 在 SQLSERVER 中快速有条件删除海量数据
- 阿拉伯数字转大写中文_财务常用sql存储过程
- SQL Server存储过程的基础说明
- 列出SQL Server中具有默认值的所有字段的语句
- 文本、Excel、Access数据导入SQL Server2000的方法
MSSQL 中的 sqlserver 数据库日志备份和恢复步骤
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 263 ::
收藏到网摘: n/a
sqlserver 数据库日志备份和恢复实现步骤 --创建测试数据库
CREATE DATABASE Db
GO
--对数据库进行备份
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT
GO
--创建测试表
CREATE TABLE Db.dbo.TB_test(ID int)
--延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)
WAITFOR DELAY '00:00:01'
GO
--假设我们现在误操作删除了 Db.dbo.TB_test 这个表
DROP TABLE Db.dbo.TB_test
--保存删除表的时间
SELECT dt=GETDATE() INTO #
GO
--在删除操作后,发现不应该删除表 Db.dbo.TB_test
--下面演示了如何恢复这个误删除的表 Db.dbo.TB_test
--首先,备份事务日志(使用事务日志才能还原到指定的时间点)
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT
GO
--接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY
GO
--将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM # --获取比表被删除的时间略早的时间
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt
GO
--查询一下,看表是否恢复
SELECT * FROM Db.dbo.TB_test
/*--结果:
ID
-----------
（所影响的行数为 0 行）
--*/
--测试成功
GO
--最后删除我们做的测试环境
DROP DATABASE Db
DROP TABLE #
评论 (0) All
