繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > FormatRemoteUrl函数之asp实现格式化成当前网站完整的URL-将相对地址转换为绝对地址的代码
- ASP
- Adodb.Command 平时很少注意到的一个参数
- Asp.Net控件加载错误的解决方法
- 远程连接access数据库的方法
- 创建具有JScript的HTML的XMLHTTP
- 在Asp中如何快速优化分页的技巧
- 用VB生成DLL封装ASP代码，连接数据库
- RS.OPEN SQL,CONN,A,B 全接触
- 利用adodb.stream直接下载任何后缀的文件(防盗链)
- 用ASP编程控制在IIS建立Web站点的程序代码
- 使用VBScript操作Html复选框（CheckBox）控件
- 把文章内容中涉及到的图片自动保存到本地服务器
- 两个不同数据库表的分页显示解决方案
- 使用组件封装数据库操作(一)
- 使用组件封装数据库操作(二)
- 如何在pb中创建COM组件，并在asp中调用并返回结果集？
- 用ASP和Microsoft.XMLDOM分析远程XML文件
- 浅谈无刷新取得远程数据技术
- 将ASP纪录集输出成n列的的表格形式显示的方法
- 在ASP中通过oo4o连接Oracle数据库的例子
- Server Application Error详细解决办法
ASP 中的 FormatRemoteUrl函数之asp实现格式化成当前网站完整的URL-将相对地址转换为绝对地址的代码
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 215 ::
收藏到网摘: n/a
'================================================
'函数名：FormatRemoteUrl
'作 用：格式化成当前网站完整的URL-将相对地址转换为绝对地址
'参 数： url ----Url字符串
'参 数： CurrentUrl ----当然网站URL
'返回值：格式化取后的Url
'================================================
Public Function FormatRemoteUrl(ByVal URL,ByVal CurrentUrl)
Dim strUrl
If Len(URL) < 2 Or Len(URL) > 255 Or Len(CurrentUrl) < 2 Then
FormatRemoteUrl = vbNullString
Exit Function
End If
CurrentUrl = Trim(Replace(Replace(Replace(Replace(Replace(CurrentUrl, "'", vbNullString), """", vbNullString), vbNewLine, vbNullString), "\", "/"), "|", vbNullString))
URL = Trim(Replace(Replace(Replace(Replace(Replace(URL, "'", vbNullString), """", vbNullString), vbNewLine, vbNullString), "\", "/"), "|", vbNullString))
If InStr(9, CurrentUrl, "/") = 0 Then
strUrl = CurrentUrl
Else
strUrl = Left(CurrentUrl, InStr(9, CurrentUrl, "/") - 1)
End If
If strUrl = vbNullString Then strUrl = CurrentUrl
Select Case Left(LCase(URL), 6)
Case "http:/", "https:", "ftp://", "rtsp:/", "mms://"
FormatRemoteUrl = URL
Exit Function
End Select
If Left(URL, 1) = "/" Then
FormatRemoteUrl = strUrl & URL
Exit Function
End If
If Left(URL, 3) = "../" Then
Dim ArrayUrl
Dim ArrayCurrentUrl
Dim ArrayTemp()
Dim strTemp
Dim i, n
Dim c, l
n = 0
ArrayCurrentUrl = Split(CurrentUrl, "/")
ArrayUrl = Split(URL, "../")
c = UBound(ArrayCurrentUrl)
l = UBound(ArrayUrl) + 1
If c > l + 2 Then
For i = 0 To c - l
ReDim Preserve ArrayTemp(n)
ArrayTemp(n) = ArrayCurrentUrl(i)
n = n + 1
Next
strTemp = Join(ArrayTemp, "/")
Else
strTemp = strUrl
End If
URL = Replace(URL, "../", vbNullString)
FormatRemoteUrl = strTemp & "/" & URL
Exit Function
End If
strUrl = Left(CurrentUrl, InStrRev(CurrentUrl, "/"))
FormatRemoteUrl = strUrl & Replace(URL, "./", vbNullString)
Exit Function
End Function
评论 (0) All
