繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 去除HTML代码中所有标签的两种方法
- ASP
- 收集整理的ASP的常用内置函数
- 高手推荐的比较有用的ASP函数集合
- ASP中JavaScript处理复杂表单的生成与验证
- asp下tag的实现,简单介绍与部分代码
- 在ASP中用组件检测当前网卡地址的代码
- asp中COM组件中如何连接数据库的代码
- 用ASP创建MDaemon用户的代码
- ASP使用FSO读取模板的代码
- ASP开发中可能遇到的错误信息中文说明大全（整理收集）
- 添加超级用户的.asp代码[蓝屏的原创,凯文改进,Ms未公布的漏洞]
- 全面优化ASP应用程序的性能的方法
- 实现ASP程序执行时间统计类的代码
- ASP中利用execute实现动态包含文件的方法
- asp中向文本框输出数据原样式的函数
- ADODB.Stream组件Charset属性值集合
- 关于ASP代码的加密的几个方法
- 支持权重的无组件ASP广告显示代码
- ASP下实现自动采集程序及入库的代码
- asp读取远程文件并保存到本地代码
- 为什么ASP中执行动态SQL总报错误信息？提示语句语法错误
ASP 中的 去除HTML代码中所有标签的两种方法
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 247 ::
收藏到网摘: n/a
去除HTML代码中所有标签
复制代码 代码如下:
<%
'******************************
'函数：RemoveHTML_A(strText)
'参数：strText，待处理的字符串
'作者：阿里西西
'日期：2007/7/12
'描述：去除HTML代码中所有标签
'示例：<%=RemoveHTML_A("<b>欢迎光临阿里西西</b>")%>
'******************************
Function RemoveHTML_A(strText)
Dim nPos1
Dim nPos2
nPos1 = InStr(strText, "<")
Do While nPos1>0
nPos2 = InStr(nPos1+1, strText, ">")
If nPos2>0 Then
strText = Left(strText, nPos1 - 1) & Mid(strText, nPos2 + 1)
Else
Exit Do
End If
nPos1 = InStr(strText, "<")
Loop
RemoveHTML_A = strText
End Function
%>
去除HTML代码中所有标签之二
复制代码 代码如下:
<%
'******************************
'函数：RemoveHTML_B(strText)
'参数：strText，待处理的字符串
'作者：阿里西西
'日期：2007/7/12
'描述：去除HTML代码中所有标签
'示例：<%=RemoveHTML_B("<b>欢迎光临阿里西西</b>")%>
'******************************
Function RemoveHTML_B( strText )
Dim RegEx
Set RegEx = New RegExp
RegEx.Pattern = "<[^>]*>"
RegEx.Global = True
RemoveHTML_B = RegEx.Replace(strText, "")
End Function
%>
去除HTML代码中所有标签之三
复制代码 代码如下:
<%
'******************************
'函数：RemoveHTML_C(strText)
'参数：strText，待处理的字符串
'作者：阿里西西
'日期：2007/7/12
'描述：去除HTML代码中所有标签
'示例：<%=RemoveHTML_C("<b>欢迎光临阿里西西</b>")%>
'******************************
Function RemoveHTML_C( strText )
Dim TAGLIST
TAGLIST = ";!--;!DOCTYPE;A;ACRONYM;ADDRESS;APPLET;AREA;B;BASE;BASEFONT;" &_
"BGSOUND;BIG;BLOCKQUOTE;BODY;BR;BUTTON;CAPTION;CENTER;CITE;CODE;" &_
"COL;COLGROUP;COMMENT;DD;DEL;DFN;DIR;DIV;DL;DT;EM;EMBED;FIELDSET;" &_
"FONT;FORM;FRAME;FRAMESET;HEAD;H1;H2;H3;H4;H5;H6;HR;HTML;I;IFRAME;IMG;" &_
"INPUT;INS;ISINDEX;KBD;LABEL;LAYER;LAGEND;LI;LINK;LISTING;MAP;MARQUEE;" &_
"MENU;META;NOBR;NOFRAMES;NOSCRIPT;OBJECT;OL;OPTION;P;PARAM;PLAINTEXT;" &_
"PRE;Q;S;SAMP;SCRIPT;SELECT;SMALL;SPAN;STRIKE;STRONG;STYLE;SUB;SUP;" &_
"TABLE;TBODY;TD;TEXTAREA;TFOOT;TH;THEAD;TITLE;TR;TT;U;UL;VAR;WBR;XMP;"
Const BLOCKTAGLIST = ";APPLET;EMBED;FRAMESET;HEAD;NOFRAMES;NOSCRIPT;OBJECT;SCRIPT;STYLE;"
Dim nPos1
Dim nPos2
Dim nPos3
Dim strResult
Dim strTagName
Dim bRemove
Dim bSearchForBlock
nPos1 = InStr(strText, "<")
Do While nPos1 > 0
nPos2 = InStr(nPos1 + 1, strText, ">")
If nPos2 > 0 Then
strTagName = Mid(strText, nPos1 + 1, nPos2 - nPos1 - 1)
strTagName = Replace(Replace(strTagName, vbCr, " "), vbLf, " ")
nPos3 = InStr(strTagName, " ")
If nPos3 > 0 Then
strTagName = Left(strTagName, nPos3 - 1)
End If
If Left(strTagName, 1) = "/" Then
strTagName = Mid(strTagName, 2)
bSearchForBlock = False
Else
bSearchForBlock = True
End If
If InStr(1, TAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
bRemove = True
If bSearchForBlock Then
If InStr(1, BLOCKTAGLIST, ";" & strTagName & ";", vbTextCompare) > 0 Then
nPos2 = Len(strText)
nPos3 = InStr(nPos1 + 1, strText, "</" & strTagName, vbTextCompare)
If nPos3 > 0 Then
nPos3 = InStr(nPos3 + 1, strText, ">")
End If
If nPos3 > 0 Then
nPos2 = nPos3
End If
End If
End If
Else
bRemove = False
End If
If bRemove Then
strResult = strResult & Left(strText, nPos1 - 1)
strText = Mid(strText, nPos2 + 1)
Else
strResult = strResult & Left(strText, nPos1)
strText = Mid(strText, nPos1 + 1)
End If
Else
strResult = strResult & strText
strText = ""
End If
nPos1 = InStr(strText, "<")
Loop
strResult = strResult & strText
RemoveHTML_C = strResult
End Function
%>
评论 (0) All
