繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp 读取 utf-8格式文档并生成utf-8格式文档的乱码问题
- ASP
- javascript asp教程More About Recordsets
- javascript asp教程添加和修改
- javascript asp教程 日期相关
- 简单的ASP分页代码（测试正确）
- 用ASP打开远端MDB文件的方法
- asp下同一空间多绑多哥域名的方法
- asp下实现替换远程文件为本地文件并保存远程文件的代码
- asp,VBscript语法错误,史上最全最详细最精确
- 讲解ASP方面的知识比较全的asp学习教程
- 给万博系统的新闻系统增加分页功能[配有详细说明]
- 在asp中通过vbs类实现rsa加密与解密的代码
- 一段在asp中加密与解密对应的函数
- 通过MSXML2自动获取QQ个人头像及在线情况(给初学者)
- 用ASP VBS xmlhttp adodbstream下载和保存图片的代码
- 厉害的用Asp获取Dll加密新闻内容
- 用正则和xmlHttp实现的asp小偷程序
- ASP之简化创建关闭记录集对象并创建使用简单的MSSQL存储过程
- ASP中怎么实现SQL数据库备份、恢复！
- asp中实现随机分组程序的代码
- asp之字符串操作函数
ASP 中的 asp 读取 utf-8格式文档并生成utf-8格式文档的乱码问题
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 77 ::
收藏到网摘: n/a
今天在对搜索吧的程序进行utf-8修正时，发现生成的utf-8格式文档存在着乱码，原来文件
create_html.asp代码如下：
复制代码 代码如下:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<%
set objrs=server.createObject("Scripting.FileSystemObject")
conn=server.mappath("example.xml")
set Stream=objrs.opentextfile(conn,1,true,-2)
content=stream.readall
Response.Write(content)
stream.close
%>
这段代码要实现的功能是：从example.xml(utf-8格式)中读取文字包括中文，然后输出，但是每次输出却都是乱码，这个问题着实困扰了我很久，后来还是在经典论坛“小韩”“萧萧小雨 ”的帮助下解决了，真是感谢他们了。
或许我一开始就是错误的，现在正确的代码修改后如下，用了“萧萧小雨”给的代码，包括了用读取的内容生成新的utf-8格式文档。详细代码如下：
复制代码 代码如下:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<% Response.CodePage=65001%>
<% Response.Charset="UTF-8" %>
<%
'申明变量
dim read_path,write_paht,content
'----读取文件内容------------------------
Function ReadTextFile(filePath,CharSet)
dim stm
set stm=Server.CreateObject("adodb.stream")
stm.Type=1 'adTypeBinary，按二进制数据读入
stm.Mode=3 'adModeReadWrite ,这里只能用3用其他会出错
stm.Open
stm.LoadFromFile filePath
stm.Position=0 '把指针移回起点
stm.Type=2 '文本数据
stm.Charset=CharSet
ReadTextFile = stm.ReadText
stm.Close
set stm=nothing
End Function
'----写入文件------------------------
Sub WriteTextFile(filePath,fileContent,CharSet)
dim stm
set stm=Server.CreateObject("adodb.stream")
stm.Type=2 'adTypeText，文本数据
stm.Mode=3 'adModeReadWrite,读取写入，此参数用2则报错
stm.Charset=CharSet
stm.Open
stm.WriteText fileContent
stm.SaveToFile filePath,2 'adSaveCreateOverWrite，文件存在则覆盖
stm.Flush
stm.Close
set stm=nothing
End Sub
'要读取的文件路径
read_path = Server.MapPath("example.xml")
'要写入的文件路径
write_path = Server.MapPath("example.asp")
'读取的文件内容
content = ReadTextFile(read_path,"utf-8")
'输出读取的文件
Response.Write(content)
'开始写入
call WriteTextFile(write_path,content,"utf-8")
%>
这段代码相当实用，对于生成utf-8格式静态页十分有用，一些必要的解释我也注明了，需要注意的是：
复制代码 代码如下:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<% Response.CodePage=65001%>
<% Response.Charset="UTF-8" %>
评论 (0) All
