繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > asp中创建多级目录的两段代码
- ASP
- 从文本文件中读取信息并存储入数据库
- 文本搜索
- FileSystemObject处理文件
- 设计 FileSystemObject
- 处理驱动器和文件夹
- 用ASP做一个TOP COOL的站内搜索
- 怎样读取一个文本文件的内容?
- 在线用表单建立文件夹
- filesystemobject组件的用法示例
- ASP中文本文件与数据库文件的数据交换(FSO)
- 读取目录下的所有文件(包括子目录下的所有文件)
- ASP中FSO的神奇功能 - FSO不能做到的
- ASP中FSO的神奇功能 - 用FSO进行内容管理
- ASP中FSO的神奇功能 - 使用FSO进行搜索
- ASP中FSO的神奇功能 - 权限许可
- ASP中FSO的神奇功能 - 文件读取
- ASP中FSO的神奇功能 - 写文件
- ASP中FSO的神奇功能 - 简介
- 读取目录下的文件得到一个数组
- 奇妙的文件系统对象组件
ASP 中的 asp中创建多级目录的两段代码
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 56 ::
收藏到网摘: n/a
复制代码 代码如下:
'==============================
'创建多级目录，可以创建不存在的根目录
'参数：要创建的目录名称，可以是多级
'创建目录的根目录从当前目录开始
'''调用举例
''Call CreateMultiFolder("/upload/jumbot/myphoto/")
'==============================
Function CreateMultiFolder(ByVal CFolder)
Dim objFSO, PhCreateFolder, CreateFolderArray, CreateFolder
Dim i, ii, CreateFolderSub, PhCreateFolderSub, BlInfo
BlInfo = False
CreateFolder = CFolder
On Error Resume Next
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
If Err Then
Err.Clear()
Exit Function
End If
If Right(CreateFolder, 1) = "/" Then
CreateFolder = Left(CreateFolder, Len(CreateFolder) -1)
End If
CreateFolderArray = Split(CreateFolder, "/")
For i = 0 To UBound(CreateFolderArray)
CreateFolderSub = ""
For ii = 0 To i
CreateFolderSub = CreateFolderSub & CreateFolderArray(ii) & "/"
Next
PhCreateFolderSub = Server.MapPath(CreateFolderSub)
If Not objFSO.FolderExists(PhCreateFolderSub) Then
objFSO.CreateFolder(PhCreateFolderSub)
End If
Next
If Err Then
Err.Clear()
Else
BlInfo = True
End If
CreateMultiFolder = BlInfo
End Function
上面的是循环
下面的是正则
复制代码 代码如下:
'==============================
''创建文件目录(多层)
''使用正则
'==============================
Function Create_N_Folder(save, ByVal Path)
Dim Fso
Set Fso = Server.CreateObject("Scripting.FileSystemObject")
If Not Fso.FolderExists(Path) Then
Dim regEx
Set regEx = New RegExp
regEx.Pattern = "^(.*)\\([^\\]*)$"
regEx.Global = False
regEx.IgnoreCase = True
save = save & regEx.Replace(Path, "$2") & "|"
Path = regEx.Replace(Path, "$1")
If Create_N_Folder(save, Path) Then Create_N_Folder = True
Set regEx = Nothing
Else
If save = "|" Then
Create_N_Folder = True
Else
Dim Temp
Temp = Mid(save, 2, Len(save) - 2)
If InStrRev(Temp, "|") = 0 Then
save = "|"
Path = Path & "\" & Temp
Else
Dim Folder
Folder = Mid(Temp, InStrRev(Temp, "|") + 1)
save = "|" & Mid(Temp, 1, InStrRev(Temp, "|") - 1) & "|"
Path = Path & "\" & Folder
End If
Fso.CreateFolder Path
If Create_N_Folder(save, Path) Then Create_N_Folder = True
End If
End If
Set Fso = Nothing
End Function
评论 (0) All
