繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > filesystemobject组件的用法示例
- ASP
- javascript asp教程More About Recordsets
- javascript asp教程添加和修改
- javascript asp教程 日期相关
- 简单的ASP分页代码（测试正确）
- 用ASP打开远端MDB文件的方法
- asp下同一空间多绑多哥域名的方法
- asp下实现替换远程文件为本地文件并保存远程文件的代码
- asp,VBscript语法错误,史上最全最详细最精确
- 讲解ASP方面的知识比较全的asp学习教程
- 给万博系统的新闻系统增加分页功能[配有详细说明]
- 在asp中通过vbs类实现rsa加密与解密的代码
- 一段在asp中加密与解密对应的函数
- 通过MSXML2自动获取QQ个人头像及在线情况(给初学者)
- 用ASP VBS xmlhttp adodbstream下载和保存图片的代码
- 厉害的用Asp获取Dll加密新闻内容
- 用正则和xmlHttp实现的asp小偷程序
- ASP之简化创建关闭记录集对象并创建使用简单的MSSQL存储过程
- ASP中怎么实现SQL数据库备份、恢复！
- asp中实现随机分组程序的代码
- asp之字符串操作函数
ASP 中的 filesystemobject组件的用法示例
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 115 ::
收藏到网摘: n/a
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' CreateLyrics
' 目的：
' 在文件夹中创建两个文本文件。
' 示范下面的内容
' - FileSystemObject.CreateTextFile
' - TextStream.WriteLine
' - TextStream.Write
' - TextStream.WriteBlankLines
' - TextStream.Close
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub CreateLyrics(Folder)
Dim TextStream
Set TextStream = Folder.CreateTextFile("OctopusGarden.txt")
TextStream.Write("Octopus' Garden ") ' 请注意，该语句不添加换行到文件中。
TextStream.WriteLine("(by Ringo Starr)")
TextStream.WriteBlankLines(1)
TextStream.WriteLine("I'd like to be under the sea in an octopus' garden in the shade,")
TextStream.WriteLine("He'd let us in, knows where we've been -- in his octopus' garden in the shade.")
TextStream.WriteBlankLines(2)
TextStream.Close
Set TextStream = Folder.CreateTextFile("BathroomWindow.txt")
TextStream.WriteLine("She Came In Through The Bathroom Window (by Lennon/McCartney)")
TextStream.WriteLine("")
TextStream.WriteLine("She came in through the bathroom window protected by a silver spoon")
TextStream.WriteLine("But now she sucks her thumb and wanders by the banks of her own lagoon")
TextStream.WriteBlankLines(2)
TextStream.Close
End Sub
' GetLyrics
' 目的：
' 显示 lyrics 文件的内容。
' 示范下面的内容
' - FileSystemObject.OpenTextFile
' - FileSystemObject.GetFile
' - TextStream.ReadAll
' - TextStream.Close
' - File.OpenAsTextStream
' - TextStream.AtEndOfStream
' - TextStream.ReadLine
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetLyrics(FSO)
Dim TextStream
Dim S
Dim File
' 有多种方法可用来打开一个文本文件，和多种方法来从文件读取数据。
' 这儿用了两种方法来打开文件和读取文件：
Set TextStream = FSO.OpenTextFile(TestFilePath & "\Beatles\OctopusGarden.txt", OpenFileForReading)
S = TextStream.ReadAll & NewLine & NewLine
TextStream.Close
Set File = FSO.GetFile(TestFilePath & "\Beatles\BathroomWindow.txt")
Set TextStream = File.OpenAsTextStream(OpenFileForReading)
Do While Not TextStream.AtEndOfStream
S = S & TextStream.ReadLine & NewLine
Loop
TextStream.Close
GetLyrics = S
End Function
评论 (0) All
