繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > filesystemobject组件的用法示例
- ASP
- 冒泡算法的三种JavaScript表示
- asp无限分级(递归调用)
- VBS、ASP代码语法加亮显示的类
- 安全脚本程序的编写 V1.0
- atom2rss.asp
- atom_js.asp
- google sitemap.asp
- 用ASP读取/写入UTF-8编码格式的文件
- 捌度空间 缓存类
- 再来个专门为google量身定做的sitemap生成代码,(可是动态的哦)
- 一个能对访问者进行编号、记录访问次数、IP、时间的统计制作实例
- 如何在ASP页面动态Inclue文件？
- 多域名一网站时如果返回最原来的域名
- 网页木马代码例子（里面的文件是漏洞扫描器，呵呵）
- ASP万用分页程序
- ASP项目中的公共翻页模块
- 在ASP中使用均速分页法提高分页速度
- 3种不同的方法生成文件
- 身份证校验算法与ASP程序
- ASP抽取数据的执行效率
ASP 中的 filesystemobject组件的用法示例
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 54 ::
收藏到网摘: n/a
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' CreateLyrics
' 目的：
' 在文件夹中创建两个文本文件。
' 示范下面的内容
' - FileSystemObject.CreateTextFile
' - TextStream.WriteLine
' - TextStream.Write
' - TextStream.WriteBlankLines
' - TextStream.Close
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub CreateLyrics(Folder)
Dim TextStream
Set TextStream = Folder.CreateTextFile("OctopusGarden.txt")
TextStream.Write("Octopus' Garden ") ' 请注意，该语句不添加换行到文件中。
TextStream.WriteLine("(by Ringo Starr)")
TextStream.WriteBlankLines(1)
TextStream.WriteLine("I'd like to be under the sea in an octopus' garden in the shade,")
TextStream.WriteLine("He'd let us in, knows where we've been -- in his octopus' garden in the shade.")
TextStream.WriteBlankLines(2)
TextStream.Close
Set TextStream = Folder.CreateTextFile("BathroomWindow.txt")
TextStream.WriteLine("She Came In Through The Bathroom Window (by Lennon/McCartney)")
TextStream.WriteLine("")
TextStream.WriteLine("She came in through the bathroom window protected by a silver spoon")
TextStream.WriteLine("But now she sucks her thumb and wanders by the banks of her own lagoon")
TextStream.WriteBlankLines(2)
TextStream.Close
End Sub
' GetLyrics
' 目的：
' 显示 lyrics 文件的内容。
' 示范下面的内容
' - FileSystemObject.OpenTextFile
' - FileSystemObject.GetFile
' - TextStream.ReadAll
' - TextStream.Close
' - File.OpenAsTextStream
' - TextStream.AtEndOfStream
' - TextStream.ReadLine
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetLyrics(FSO)
Dim TextStream
Dim S
Dim File
' 有多种方法可用来打开一个文本文件，和多种方法来从文件读取数据。
' 这儿用了两种方法来打开文件和读取文件：
Set TextStream = FSO.OpenTextFile(TestFilePath & "\Beatles\OctopusGarden.txt", OpenFileForReading)
S = TextStream.ReadAll & NewLine & NewLine
TextStream.Close
Set File = FSO.GetFile(TestFilePath & "\Beatles\BathroomWindow.txt")
Set TextStream = File.OpenAsTextStream(OpenFileForReading)
Do While Not TextStream.AtEndOfStream
S = S & TextStream.ReadLine & NewLine
Loop
TextStream.Close
GetLyrics = S
End Function
评论 (0) All
