繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > filesystemobject组件的用法示例
- ASP
- 用ASP发 WAP MAIL(-)
- 使用纯粹的asp+语言制作的栏目管理(一)
- 使用ASP方便的建立自己网站的每日更新
- 中文虚拟域名实现(1) (环境：中文NT)
- 中文虚拟域名实现(2) (环境：中文NT)
- 中文虚拟域名实现(3) (环境：中文NT)
- 最简单的ASP聊天室（附源码）
- Win2k IIS 远程执行命令漏洞
- 搜索按钮(客户端表单)
- 转换字符串带有http://的超级链接字符串为真正的超级链接(源码)
- 第一个ASP组件:设置服务器日期时间组件
- 虹雨的功能较全的计数程序
- 下拉框连动的小例子（数据库版）
- 下拉框连动的小例子（.htm版）
- 纯ASP上传图像文件到数据库的最佳例子
- 数组数据排序的程序例子
- 网络精英计数器源程序
- 全文本检索的应用(1)
- 全文本检索的应用(2)
- 全文本检索的应用(3)
ASP 中的 filesystemobject组件的用法示例
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 76 ::
收藏到网摘: n/a
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' CreateLyrics
' 目的：
' 在文件夹中创建两个文本文件。
' 示范下面的内容
' - FileSystemObject.CreateTextFile
' - TextStream.WriteLine
' - TextStream.Write
' - TextStream.WriteBlankLines
' - TextStream.Close
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub CreateLyrics(Folder)
Dim TextStream
Set TextStream = Folder.CreateTextFile("OctopusGarden.txt")
TextStream.Write("Octopus' Garden ") ' 请注意，该语句不添加换行到文件中。
TextStream.WriteLine("(by Ringo Starr)")
TextStream.WriteBlankLines(1)
TextStream.WriteLine("I'd like to be under the sea in an octopus' garden in the shade,")
TextStream.WriteLine("He'd let us in, knows where we've been -- in his octopus' garden in the shade.")
TextStream.WriteBlankLines(2)
TextStream.Close
Set TextStream = Folder.CreateTextFile("BathroomWindow.txt")
TextStream.WriteLine("She Came In Through The Bathroom Window (by Lennon/McCartney)")
TextStream.WriteLine("")
TextStream.WriteLine("She came in through the bathroom window protected by a silver spoon")
TextStream.WriteLine("But now she sucks her thumb and wanders by the banks of her own lagoon")
TextStream.WriteBlankLines(2)
TextStream.Close
End Sub
' GetLyrics
' 目的：
' 显示 lyrics 文件的内容。
' 示范下面的内容
' - FileSystemObject.OpenTextFile
' - FileSystemObject.GetFile
' - TextStream.ReadAll
' - TextStream.Close
' - File.OpenAsTextStream
' - TextStream.AtEndOfStream
' - TextStream.ReadLine
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Function GetLyrics(FSO)
Dim TextStream
Dim S
Dim File
' 有多种方法可用来打开一个文本文件，和多种方法来从文件读取数据。
' 这儿用了两种方法来打开文件和读取文件：
Set TextStream = FSO.OpenTextFile(TestFilePath & "\Beatles\OctopusGarden.txt", OpenFileForReading)
S = TextStream.ReadAll & NewLine & NewLine
TextStream.Close
Set File = FSO.GetFile(TestFilePath & "\Beatles\BathroomWindow.txt")
Set TextStream = File.OpenAsTextStream(OpenFileForReading)
Do While Not TextStream.AtEndOfStream
S = S & TextStream.ReadLine & NewLine
Loop
TextStream.Close
GetLyrics = S
End Function
评论 (0) All
