繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 一个asp快速字符串连接类
- ASP
- asp分页（自己整理的2个分页程序）
- ASP常用的系统配置函数
- 雨哲防采集策略之列表篇
- 雨哲浅谈关于防采集而不影响收录内容篇
- asp数据库连接函数
- ajax XMLHTTP Post Form时的表单乱码综合解决
- ASP注入详细命令40条
- 用ASP实现MSSQL用户密码破解
- ASP创建对象的两种方法比较
- ASP字符串转换为整形、双精度型、布尔
- ASP计算str2在str1中出现的次数
- asp采集抓取网上房产信息的代码
- ASP注册登陆实例代码
- ASP中使用FileSystemObject时提高性能的方法
- 分享一个好东东,动态Include文件 (Dynamic File Includes)
- 解决 JScript 中使用日期类型数据时出现类型错误的问题
- 在ASP里面创建GUID
- 在JScript中使用缓存技术的实际代码
- ASP javascript Application对象的Contents和StaticObjects做Cache的一些经验
- 海阳2006+功能中的潜水王
ASP 中的 一个asp快速字符串连接类
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 156 ::
收藏到网摘: n/a
<%
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'快速字符串连接类
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'名称：Class_FastString
'来源：http://www.jansfreeware.com
'整理：qihangnet
'更新：2005年6月15日
'作用：高效地进行字符串连接，比 str = str & "abc"的方法快很多
'授权：免费使用
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Class Class_FastString
'************************************
'变量定义
'************************************
'index --- 字符串数组的下标
'ub ------ 用于调整数组度数的整数变量
'ar() ---- 字符串数组
Private index, ub, ar()
'************************************
'实例 初始化/终止
'************************************
Private Sub Class_Initialize()
Redim ar(50)
index = 0
ub = 49
End Sub
Private Sub Class_Terminate()
Erase ar
End Sub
'************************************
'事件
'************************************
'默认事件，添加字符串
Public Default Sub Add(value)
ar(index) = value
index = index+1
If index>ub Then
ub = ub + 50
Redim Preserve ar(ub)
End if
End Sub
'************************************
'方法
'************************************
'返回连接后的字符串
Public Function Dump
Redim preserve ar(index-1)
Dump = join(ar,"") '关键所在哦^_^
End Function
End class
%>
评论 (0) All
