繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > 一个asp快速字符串连接类
- ASP
- isNull(str), isEmpty(str)和 str = 的区别
- 使用ADO批量更新记录（源代码）
- 自己动手，结合javascript和dhtml做一个ubb编辑器
- 检查Email地址的比较完善的正则表达式函数
- 从Access数据库恢复BMP图像并显示在WEB页面(microsoft)
- ASP环境下邮件列表功能的实现 （四）（推荐）
- 在ASP应用中如何限制同一表单被多次提交！！！！好东西
- 了解MSMQ，控制ASP进程 （一）
- 了解MSMQ，控制ASP进程 （二）
- ASP技术在论坛中的运用(一)（吐血推荐！！！！）
- ASP技术在论坛中的运用(二)（吐血推荐！！！！）
- ASP技术在论坛中的运用(三)（吐血推荐！！！！）
- ASP技术在论坛中的运用(四)（吐血推荐！！！！）
- ASP技术在论坛中的运用(五)（吐血推荐！！！！）
- ASP技术在论坛中的运用(六)（吐血推荐！！！！）
- ASP技术在论坛中的运用(七)（吐血推荐！！！！）
- ASP技术在论坛中的运用(八)（吐血推荐！！！！）
- 不用数据源打开数据库（DSNless connection)
- 大部分的ADO的错误码对应的含义
- 好东西，翻页程序，大家可以参考
ASP 中的 一个asp快速字符串连接类
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 159 ::
收藏到网摘: n/a
<%
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'快速字符串连接类
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
'名称：Class_FastString
'来源：http://www.jansfreeware.com
'整理：qihangnet
'更新：2005年6月15日
'作用：高效地进行字符串连接，比 str = str & "abc"的方法快很多
'授权：免费使用
'%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
Class Class_FastString
'************************************
'变量定义
'************************************
'index --- 字符串数组的下标
'ub ------ 用于调整数组度数的整数变量
'ar() ---- 字符串数组
Private index, ub, ar()
'************************************
'实例 初始化/终止
'************************************
Private Sub Class_Initialize()
Redim ar(50)
index = 0
ub = 49
End Sub
Private Sub Class_Terminate()
Erase ar
End Sub
'************************************
'事件
'************************************
'默认事件，添加字符串
Public Default Sub Add(value)
ar(index) = value
index = index+1
If index>ub Then
ub = ub + 50
Redim Preserve ar(ub)
End if
End Sub
'************************************
'方法
'************************************
'返回连接后的字符串
Public Function Dump
Redim preserve ar(index-1)
Dump = join(ar,"") '关键所在哦^_^
End Function
End class
%>
评论 (0) All
