繁體中文当前位置: 首页 > 图文教程 > 网络编程 > ASP > ASP中通过该日历算法实现的具体代码
- ASP
- ASP六大对象介绍
- 使用Filter实现信息的二次检索
- 让弹出窗口变得“听话”一些
- 在ASP中利用“正则表达式” 对象实现UBB风格的论坛
- “Web 匿名用户”帐户密码的位置
- 对一些编程初学者的良言警句
- ASP编程中15个非常有用的例子
- 精彩:ASP遗留的二十大积习
- 关于Asp代码与页面的分离
- 教大家如何利用ASP打造网站论坛DIY(1)
- 教大家如何利用ASP打造网站论坛DIY(2)
- 网站安全：防范ASP木马的十大基本原则
- 用ASP设计一个留言薄
- 趣味访客计数器设计两则
- 我的ASP之旅—二级联动菜单制作
- ASP编程--新手上路篇：ASP技术简介
- 用ASP实现网上考试系统
- 请注意！常见的ASP脚本攻击及防范技巧
- ASP开发的WAP格式简易邮件系统实例
- asp基础教程：网页间数据传递方法小结
ASP中通过该日历算法实现的具体代码
出处:互联网 整理: 软晨网（RuanChen.com） 发布: 2009-09-13 浏览: 244 ::
收藏到网摘: n/a
复制代码 代码如下:
<style>
td { font-family: "宋体"; font-size:9pt}
</style>
<body bgcolor="eeeeee">
<table width="180" cellpadding="0" cellspacing="1" bgcolor="dddddd" align=center>
<%
'以下为ASP中通过该日历算法实现的具体代码
'先判断是否指定了一个年份和月份，没有则根据当前的年和月份显示
If Request("ReqDate")="" then
CurrentDate=Date
else
CurrentDate=Trim(Request("ReqDate"))
end if
pyear=year(CurrentDate)
pmonth=month(CurrentDate)
'以下的代码生成日历显示的表格头内容
%>
<tr align="LEFT" bgcolor="#dddddd">
<td width="14%" height="19" align="center">
<input type="button" value="<<" onclick="JavaScript:location.href='?ReqDate=<%=DateAdd("m",-1,CurrentDate) %>'">
</td>
<td colspan="5" align="center">
<%=pyear%>年<%=pmonth%>月
</td>
<td width="14%" align="center">
<input type="button" value=">>" onclick="JavaScript:location.href='?ReqDate=<%=DateAdd("m",1,CurrentDate)%>'">
</td>
</tr>
<tr align="center" bgcolor="#CCCCCC">
<td width="14%" height="19"> 日</td>
<td width="14%"> 一</td>
<td width="14%"> 二</td>
<td width="14%"> 三</td>
<td width="14%"> 四</td>
<td width="14%"> 五</td>
<td width="14%"> 六</td>
</tr>
<tr align=center bgcolor=ffffff height=19>
<%
'由于ASP中没有获取指定月共有多少天的函数，因此我们需要通过其他算法来获得，算法其实很简单，就是计算一下要显示月份的1日至下个月的1日一共相差几天
fromDate = FormatDateTime(month(CurrentDate) & "/1/" & year(CurrentDate))
toDate = FormatDateTime(DateAdd("m",1,fromDate))
'获得要显示月份的第一天为周几
nunmonthstart=weekday(fromDate)-1
'获得要显示的1日至下个月的1日一共相差几天(月份一共有多少天)
nunmonthend=DateDiff("d",fromDate,toDate)
'判断显示日历需要用几行表格来显示（每行显示7天）
if nunmonthstart+nunmonthend<36 then
maxi=36
else
maxi=43
end if
'循环生成表格并显示
i=1
do while i<maxi
iv=i-nunmonthstart
if i>nunmonthstart and i<=nunmonthend+nunmonthstart then
'如果为显示的是今天则用红色背景显示
if iv=Day(now) and month(now)=pmonth and year(now)=pyear then
response.write( "<td align=center bgcolor=#ffaaaa><a href='#' target=_blank>" & iv & "</a></td>")
else
response.write( "<td align=center><a href='#' target=_blank>" & iv & "</a></td>")
end if
else
response.write( "<td> </td>")
end if
'如果能被7整除（每行显示7个）则输出一个换行
if i mod 7=0 then
response.write( "</tr><tr align=center bgcolor=ffffff height=19>")
end if
i=i+1
loop
%>
</table>
</body></html>
评论 (0) All
